query-fd72338914131f61473ea61197dc8cd5

rq turtle/ttl

select Australian women who have an enwiki article and are said to be usyd alumni

but wikidata does not assert "educated at Sydney Uni"

SELECT ?item ?itemLabel ?article ?sitelink WHERE { { ?item wdt:P21 wd:Q6581072. # is a woman ?item wdt:P27 wd:Q408. # Is Australian ?sitelink ^schema:name ?article . ?article schema:about ?item ; schema:isPartOf https://en.wikipedia.org/ . } MINUS { ?item wdt:P69 wd:Q487556. # educated at Sydney University ?item wdt:P21 wd:Q6581072. # is a woman ?item wdt:P27 wd:Q408. # Is Australian } { SERVICE wikibase:mwapi { bd:serviceParam wikibase:api "Search" . bd:serviceParam wikibase:endpoint "en.wikipedia.org" . bd:serviceParam mwapi:srnamespace "0" . bd:serviceParam mwapi:srlimit "max" . bd:serviceParam mwapi:srwhat "text" . bd:serviceParam mwapi:srsearch 'insource:"Category:University of Sydney alumni"' . ?title wikibase:apiOutput mwapi:title . } BIND (STRLANG(?title, "en") as ?sitelink) } SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } } LIMIT 10

Use at

• https://query.wikidata.org/sparql

PREFIX mwapi: <http://wikiba.se/ontology#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# select Australian women who have an enwiki article and are said to be usyd alumni
# but wikidata does not assert "educated at Sydney Uni"
SELECT ?item ?itemLabel  ?article ?sitelink
WHERE 
{
  {
    ?item wdt:P21 wd:Q6581072. # is a woman
    ?item wdt:P27 wd:Q408.     # Is Australian
    ?sitelink ^schema:name ?article .
    ?article schema:about ?item ;
             schema:isPartOf <https://en.wikipedia.org/> .
  }
MINUS    { ?item wdt:P69 wd:Q487556.  # educated at Sydney University
           ?item wdt:P21 wd:Q6581072. # is a woman
           ?item wdt:P27 wd:Q408.     # Is Australian
          } 
  {
    SERVICE wikibase:mwapi
    {
      bd:serviceParam wikibase:api "Search" .
      bd:serviceParam wikibase:endpoint "en.wikipedia.org" .
      bd:serviceParam mwapi:srnamespace "0" .
      bd:serviceParam mwapi:srlimit "max" .
      bd:serviceParam mwapi:srwhat "text" .
      bd:serviceParam mwapi:srsearch 'insource:"Category:University of Sydney alumni"' .
      ?title wikibase:apiOutput mwapi:title .
    }
    BIND (STRLANG(?title, "en") as ?sitelink)
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 10

Query found at

• https://www.wikidata.org/wiki/User:MargaretRDonald/MarieCurietimelineAndVolcanoes