query-f8d6de3dfe1091ce86457c1a28b1ffb2

rq turtle/ttl

Seiten im deutschen Wikipedia mit Bezug zu München Hierzu wird Property P131 ausgewertet. Eine SPARQL Abfrage, die Seiten mit Bezug zu München in einer Tabelle mit titel, Art des Objekts, der Verwaltungseinheit, URL des Artikels, Qitem und Geokoordinaten in eine Tabelle auflistet.

Use at

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Table
#title: Wikipediaseiten mit Bezug zu München
SELECT ?page_title (GROUP_CONCAT(DISTINCT ?instanceLabel; SEPARATOR = ", ") AS ?ist_ein) (GROUP_CONCAT(DISTINCT ?velabel; SEPARATOR = ", ") AS ?verwaltungseinheiten) ?article ?item ?bild ?comkat ?location WHERE {
  ?item (wdt:P131*) ?top.
  BIND(wd:Q1726 AS ?top)
  ?item wdt:P131 ?ve.
  OPTIONAL { ?item wdt:P31 ?instance. }
  OPTIONAL { ?item wdt:P625 ?location. }
  OPTIONAL {
    ?article schema:about ?item;
      schema:isPartOf <https://de.wikipedia.org/>;
      schema:name ?page_title.
  }
  OPTIONAL { ?item wdt:P18 ?bild. }
  OPTIONAL { ?item wdt:P373 ?commons. }
  BIND(IF(BOUND(?commons), URI(CONCAT("https://commons.wikimedia.org/wiki/Category:", STR(?commons))), "") AS ?comkat)
  FILTER(BOUND(?article))
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?instance rdfs:label ?instanceLabel.
    ?ve rdfs:label ?velabel.
  }
}
GROUP BY ?item ?page_title ?article ?bild ?comkat ?location
ORDER BY (?verwaltungseinheiten)

Query found at