query-f6053fae3caa8b77c748e188e3d23535

rq turtle/ttl

図書館およびその下位クラスに分類されている項目のクラスごとの件数（日本国内のみ） 日本国内の図書館及びその下位クラスに分類されている項目の件数を一覧する

Use at

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?aggType ?subclassLabel ?count (?subclass AS ?subclassEntity) 
WHERE {
  {
    #　subclassのエンティティとsubclassごとの合計件数
    SELECT ?subclass (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31 ?subclass.
      ?subclass wdt:P279* wd:Q7075.
      ?library wdt:P17 wd:Q17.
    }
    GROUP BY ?subclass
  }
  UNION
  {
    #　subclassごとの合計のさらに合計（延べ件数＝複数のsubclassに分類されている場合はそれぞれを1件と数える＝件数に重複あり）
    SELECT ("延べ件数" AS ?aggType) (SUM(?count) AS ?count)
    WHERE {
      {
        SELECT (COUNT(DISTINCT ?library) AS ?count)  #　subclassごとの合計
        WHERE {
          ?library wdt:P31 ?subclass.
          ?subclass wdt:P279* wd:Q7075.
          ?library wdt:P17 wd:Q17.
        }
        GROUP BY ?subclass
      }
    }
  }
  UNION
  {
    #　項目のユニーク件数（複数のsubclassに分類されている場合でもIDが同じなら合わせて1件＝件数に重複なし）
    SELECT ("ユニーク件数" AS ?aggType) (COUNT(DISTINCT ?library) AS ?count)
    WHERE {
      ?library wdt:P31/wdt:P279* wd:Q7075.
      ?library wdt:P17 wd:Q17.
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], ja, en" . }
}
ORDER BY DESC(?count)

Query found at