query-eeeead82e7b9ad2e63e63a58ecd5b449

rq turtle/ttl

Finds items with the anti-pattern of:

described by source=article

reference: inferred by=article

described by source=DNB

statement is subject of=article

which duplicates (triplicates) and self-references the article link.

SELECT DISTINCT ?item ?article WHERE { ?item p:P1343 ?articleURI; p:P1343 ?sourceURI.

?articleURI ps:P1343 ?article; prov:wasDerivedFrom ?articleRef. ?articleRef pr:P3452 ?article.

?sourceURI ps:P1343 ?source; pq:P805 ?article. }

Use at

• https://query.wikidata.org/sparql

PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
# Finds items with the anti-pattern of:
#   described by source=article
#     reference: inferred by=article
#   described by source=DNB
#     statement is subject of=article
# which duplicates (triplicates) and self-references the article link.

SELECT DISTINCT ?item ?article WHERE {
  ?item p:P1343 ?articleURI;
        p:P1343 ?sourceURI.

  ?articleURI ps:P1343 ?article;
              prov:wasDerivedFrom ?articleRef.
  ?articleRef pr:P3452 ?article.

  ?sourceURI ps:P1343 ?source;
             pq:P805 ?article.
}

Query found at

• https://www.wikidata.org/wiki/Wikidata:Edit_groups/QSv2/4364