query-eabcd0014e4ce0f708e72f1d756e18a4

rq turtle/ttl

Au 7 septembre 1973, il y a 25 régions. SELECT DISTINCT ?inseeRégion ?région ?nom WHERE { BIND ( "1973-09-07"^^xsd:dateTime as ?dateRecherche )

?région p:P2585 ?P2585node . # existence d'un code Insee ?P2585node ps:P2585 ?inseeRégion . # valeur du code Insee OPTIONAL { ?région wdt:P571 ?dateCréation . } # date de création OPTIONAL { ?région wdt:P576 ?dateDissolution . } # date de dissolution

?région p:P1448 ?P1448node . # existence d'un nom ?P1448node ps:P1448 ?nom . # valeur du nom FILTER( lang(?nom)="fr" ). # nom en français MINUS { ?P1448node pq:P3831 wd:Q96406455 . } # nom long MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom

OPTIONAL {?région p:P31 [ps:P31 wd:Q36784; pq:P580 ?dateRégionalisation].} FILTER ( !BOUND(?dateRégionalisation) || ?dateRégionalisation <= ?dateRecherche ) # régionalisation outre-mer

FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # ancienne région
FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # future région 
FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom

} ORDER BY ?inseeRégion

Use at

• https://query.wikidata.org/sparql

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
# Au 7 septembre 1973, il y a 25 régions.
SELECT DISTINCT ?inseeRégion ?région ?nom WHERE {
  BIND ( "1973-09-07"^^xsd:date as ?dateRecherche ) 

   ?région p:P2585 ?P2585node . # existence d'un code Insee
    ?P2585node ps:P2585 ?inseeRégion . # valeur du code Insee
    OPTIONAL { ?région wdt:P571 ?dateCréation . } # date de création
    OPTIONAL { ?région wdt:P576 ?dateDissolution . } # date de dissolution

   ?région p:P1448 ?P1448node . # existence d'un nom
    ?P1448node ps:P1448 ?nom . # valeur du nom
    FILTER( lang(?nom)="fr" ). # nom en français
    MINUS { ?P1448node pq:P3831 wd:Q96406455 . } # nom long
    MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
    OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
    OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom 

   OPTIONAL {?région p:P31 [ps:P31 wd:Q36784; pq:P580 ?dateRégionalisation].}
    FILTER ( !BOUND(?dateRégionalisation) || ?dateRégionalisation <= ?dateRecherche ) # régionalisation outre-mer

    FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # ancienne région
    FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # future région 
    FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
    FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom   
}
ORDER BY ?inseeRégion

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_France/Liste_des_r%C3%A9gions