query-de1a9f7ffbbecb15195af972a2edc385

rq turtle/ttl

MPs, and the different seats they sat for

counting on label takes account of the fact that some seats are split by Wikidata

and this is slightly counterintuitive (a reader might reasonably treat them as the same place)

see eg Ian Mikardo at Reading; the constituency 1885-1950 & 1955-1974 are distinct items

if we counted by ?constituency then he would total six, but really two are the "same" seat

select ?mp ?mpLabel ?seatcount ?seats WHERE { { SELECT ?mp ?mpLabel (COUNT(DISTINCT ?constituencyLabel) AS ?seatcount) (GROUP_CONCAT(DISTINCT(?constituencyLabel); separator=", ") as ?seats) WHERE { ?position wdt:P279 wd:Q16707842. ?mp p:P39 ?positionStatement . ?positionStatement ps:P39 ?position ; pq:P768 ?constituency . SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . ?mp rdfs:label ?mpLabel . ?constituency rdfs:label ?constituencyLabel } } GROUP BY ?mp ?mpLabel } filter(?seatcount >4) } order by desc(?seatcount)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# MPs, and the different seats they sat for
# counting on label takes account of the fact that some seats are split by Wikidata
# and this is slightly counterintuitive (a reader might reasonably treat them as the same place)
# see eg Ian Mikardo at Reading; the constituency 1885-1950 & 1955-1974 are distinct items
# if we counted by ?constituency then he would total six, but really two are the "same" seat

select ?mp ?mpLabel ?seatcount ?seats
WHERE {
       {
        SELECT ?mp ?mpLabel (COUNT(DISTINCT ?constituencyLabel) AS ?seatcount) (GROUP_CONCAT(DISTINCT(?constituencyLabel); separator=", ") as ?seats)
         WHERE {
         ?position wdt:P279 wd:Q16707842.
         ?mp p:P39 ?positionStatement . ?positionStatement ps:P39 ?position ; pq:P768 ?constituency .
         SERVICE wikibase:label {
               bd:serviceParam wikibase:language "en" .
               ?mp rdfs:label ?mpLabel .
               ?constituency rdfs:label ?constituencyLabel }
        } GROUP BY ?mp ?mpLabel 
       }
  filter(?seatcount >4)
} 
order by desc(?seatcount)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_British_Politicians/Sample_Queries