query-d92d03c37ea13d34d1e6f105ef76178a

rq turtle/ttl

Top 100 Biography articles available on most wikis, but not yet created on Central Kurdish WikipediaReferenced from above query.

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?item ?enwiki ?numOfSitelinks ?genderLabel (GROUP_CONCAT(DISTINCT ?citizenshipLabel; separator="؛ ") AS ?citizenships)
WHERE {
  {
    SELECT DISTINCT ?item ?enwiki ?numOfSitelinks ?genderLabel ?citizenshipLabel
    WHERE {
      ?item wdt:P31 wd:Q5 .
      ?item wikibase:sitelinks ?numOfSitelinks . 

      FILTER (?numOfSitelinks > 70) 

      OPTIONAL {
        ?item wdt:P21 ?gender .
        ?gender rdfs:label ?genderLabel .
        FILTER(LANG(?genderLabel) = "ckb")
      }

      OPTIONAL {
        ?item wdt:P27 ?citizenship .
        ?citizenship rdfs:label ?citizenshipLabel .
        FILTER(LANG(?citizenshipLabel) = "ckb")
      }

      OPTIONAL {
        ?enwikiPage schema:about ?item ;
                    schema:isPartOf <https://en.wikipedia.org/> ;
                    schema:name ?enTitle .
        BIND(CONCAT("[[:en:", ?enTitle, "|", ?enTitle, "]]") AS ?enwiki)
      }

      MINUS {
        ?cat schema:isPartOf <https://ckb.wikipedia.org/> ;
             schema:about ?item .
      }
    }
  }
}
GROUP BY ?item ?enwiki ?numOfSitelinks ?genderLabel
ORDER BY DESC(?numOfSitelinks) 
LIMIT 100

Query found at

• https://www.wikidata.org/wiki/User:AramBot