query-d7d24dce719435eb83145dcff70a92c6
Communes avec les départements. Au 1er janvier 2021, il y avait 34 965 communes en France. SELECT ?insee ?commune ?nom ?inseeDépartement ?département WHERE { BIND ( "2021-01-01"^^xsd:dateTime as ?dateRecherche ) # Au 1er janvier 2021 ?commune p:P374 ?P374node . # existence d'un code Insee ?P374node ps:P374 ?insee . # valeur du code Insee OPTIONAL { ?P374node pq:P580 ?dateDébutCode . } # date de début du code Insee OPTIONAL { ?P374node pq:P582 ?dateFinCode . } # date de fin du code Insee FILTER ( !BOUND(?dateDébutCode) || ?dateDébutCode <= ?dateRecherche ) # ancien code Insee FILTER ( !BOUND(?dateFinCode) || ?dateFinCode > ?dateRecherche ) # futur code Insee { ?commune wdt:P31 wd:Q484170 . # nature de commune OPTIONAL { ?commune wdt:P571 ?dateCréation . } # date de création OPTIONAL { ?commune wdt:P576 ?dateDissolution . } # date de dissolution
?département wdt:P2586 ?inseeDépartement. # code Insee du département
?commune p:P131 ?P131node .
?P131node ps:P131 ?département . # valeur du département
MINUS { ?P131node pq:P1013 wd:Q583865 . } # département collectivité
OPTIONAL { ?P131node pq:P580 ?dateDébutDépartement . } # date de début du département
OPTIONAL { ?P131node pq:P582 ?dateFinDépartement . } # date de fin du département
}
UNION { VALUES (?commune ?inseeDépartement ?inseeArrondissement ) {(wd:Q90 "75" "751")} } # Paris
FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # communes futures
FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # communes passées
FILTER ( !BOUND(?dateDébutDépartement) || ?dateDébutDépartement <= ?dateRecherche ) # ancien département
FILTER ( !BOUND(?dateFinDépartement) || ?dateFinDépartement > ?dateRecherche ) # futur département
?commune p:P1448 ?P1448node . # existence d'un nom
?P1448node ps:P1448 ?nom . # valeur du nom
FILTER( lang(?nom)="fr" ). # nom en français
MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom
FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom
}
ORDER BY (?insee)
Use at
- https://query.wikidata.org/sparql
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
# Communes avec les départements. Au 1er janvier 2021, il y avait 34 965 communes en France.
SELECT ?insee ?commune ?nom ?inseeDépartement ?département
WHERE {
BIND ( "2021-01-01"^^xsd:date as ?dateRecherche ) # Au 1er janvier 2021
?commune p:P374 ?P374node . # existence d'un code Insee
?P374node ps:P374 ?insee . # valeur du code Insee
OPTIONAL { ?P374node pq:P580 ?dateDébutCode . } # date de début du code Insee
OPTIONAL { ?P374node pq:P582 ?dateFinCode . } # date de fin du code Insee
FILTER ( !BOUND(?dateDébutCode) || ?dateDébutCode <= ?dateRecherche ) # ancien code Insee
FILTER ( !BOUND(?dateFinCode) || ?dateFinCode > ?dateRecherche ) # futur code Insee
{
?commune wdt:P31 wd:Q484170 . # nature de commune
OPTIONAL { ?commune wdt:P571 ?dateCréation . } # date de création
OPTIONAL { ?commune wdt:P576 ?dateDissolution . } # date de dissolution
?département wdt:P2586 ?inseeDépartement. # code Insee du département
?commune p:P131 ?P131node .
?P131node ps:P131 ?département . # valeur du département
MINUS { ?P131node pq:P1013 wd:Q583865 . } # département collectivité
OPTIONAL { ?P131node pq:P580 ?dateDébutDépartement . } # date de début du département
OPTIONAL { ?P131node pq:P582 ?dateFinDépartement . } # date de fin du département
}
UNION { VALUES (?commune ?inseeDépartement ?inseeArrondissement ) {(wd:Q90 "75" "751")} } # Paris
FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # communes futures
FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # communes passées
FILTER ( !BOUND(?dateDébutDépartement) || ?dateDébutDépartement <= ?dateRecherche ) # ancien département
FILTER ( !BOUND(?dateFinDépartement) || ?dateFinDépartement > ?dateRecherche ) # futur département
?commune p:P1448 ?P1448node . # existence d'un nom
?P1448node ps:P1448 ?nom . # valeur du nom
FILTER( lang(?nom)="fr" ). # nom en français
MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom
FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom
}
ORDER BY (?insee)