query-d64c49a08b2db666354e1bafe72ba344

rq turtle/ttl

title: Wikidata statements with a retracted paper as reference SELECT DISTINCT ?entity ?entityLabel ?propertyLabel ?valueLabel ?retracted ?retractedLabel WITH { SELECT DISTINCT ?entity ?p ?statement ?retracted WHERE { ?retracted wdt:P31 wd:Q45182324 . ?entity ?p ?statement . ?statement prov:wasDerivedFrom / pr:P248 ?retracted . } } AS %STATEMENTS WHERE { INCLUDE %STATEMENTS ?p ^wikibase:claim ?property . ?statement ?ps ?value . ?ps ^wikibase:statementProperty ?property . SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } }

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#title: Wikidata statements with a retracted paper as reference
SELECT DISTINCT ?entity ?entityLabel ?propertyLabel ?valueLabel ?retracted ?retractedLabel WHERE {
   {
  SELECT DISTINCT ?entity ?p ?statement ?retracted WHERE {
    ?retracted wdt:P31 wd:Q45182324 .
    ?entity ?p ?statement .
    ?statement prov:wasDerivedFrom / pr:P248 ?retracted .
  }
}  ?p ^wikibase:claim ?property .
  ?statement ?ps ?value .
  ?ps ^wikibase:statementProperty ?property .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Retractions/SPARQL