query-d317001e1a5adef62df4834671625d0e

rq turtle/ttl

Propertiesinstance of (P31)subclass of (P279)publication date (P577)part of the series (P179)followed by (P156)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?game ?gameLabel ?original_date_game ?sequel ?sequelLabel ?original_date_sequel ?interval ?series ?seriesLabel WHERE {
  {
    SELECT ?game ?gameLabel (MIN(?game_date) AS ?original_date_game) ?sequel ?sequelLabel (MIN(?sequel_date) AS ?original_date_sequel) ?series ?seriesLabel WHERE {
      ?game wdt:P31/wdt:P279* wd:Q7889;
        wdt:P577 ?game_date;
        p:P179 ?series_statement.
      ?series_statement pq:P156 ?sequel;
        ps:P179 ?series.
      ?sequel wdt:P577 ?sequel_date.
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }
    GROUP BY ?game ?gameLabel ?sequel ?sequelLabel ?series ?seriesLabel
  }
  BIND(?original_date_sequel - ?original_date_game AS ?interval)
  FILTER ( ?interval < 0 )
}

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Video_games/Queries