query-ca0e9ab70873ed2b273b26a7461f03d7

rq turtle/ttl

Усе трансы ў беларускай Вікіпэдыі SELECT ?item ?itemLabel ?pic ?stateLabel (GROUP_CONCAT(DISTINCT ?job; SEPARATOR=", ") AS ?jobs) ?nationLabel WHERE { ?item wdt:P31 wd:Q5. # людзі { ?item wdt:P21 wd:Q1052281. } # транс UNION { ?item wdt:P21 wd:Q2449503. } # транс OPTIONAL { ?item wdt:P18 ?pic. } OPTIONAL { ?item wdt:P27 ?state. } OPTIONAL { ?item wdt:P106 [rdfs:label ?job]. FILTER(LANG(?job)='be-tarask'). } OPTIONAL { ?item wdt:P172 ?nation. }

?article schema:about ?item. # якія маюць артыкул ?article schema:isPartOf https://be-tarask.wikipedia.org/. # у беларускай Вікіпэдыі

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,en,ru". } } GROUP BY ?item ?itemLabel ?pic ?stateLabel ?nationLabel

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
#Усе трансы ў беларускай Вікіпэдыі
SELECT ?item ?itemLabel ?pic ?stateLabel (GROUP_CONCAT(DISTINCT ?job; SEPARATOR=", ") AS ?jobs) ?nationLabel
WHERE {
  ?item wdt:P31 wd:Q5. # людзі
  { ?item wdt:P21 wd:Q1052281. }   # транс
  UNION
  { ?item wdt:P21 wd:Q2449503. }   # транс
  OPTIONAL { ?item wdt:P18 ?pic. }
  OPTIONAL { ?item wdt:P27 ?state. }
  OPTIONAL { ?item wdt:P106 [rdfs:label ?job]. FILTER(LANG(?job)='be-tarask'). }
  OPTIONAL { ?item wdt:P172 ?nation. }

  ?article schema:about ?item. # якія маюць артыкул
  ?article schema:isPartOf <https://be-tarask.wikipedia.org/>. # у *беларускай* Вікіпэдыі

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,en,ru". }
}
GROUP BY ?item ?itemLabel ?pic ?stateLabel ?nationLabel

Query found at

• https://www.wikidata.org/wiki/User:Taravyvan_Adijene/SPARQL