query-c7609a7669aeff10914db3da4ab676c2

rq turtle/ttl

Associo agli Elementi Wikidata (Musei) la corrispondente descrizione estesa presente nel db unico Mibact (beniculturali.it)

Tramite id ICCD in Wikidata

Query ottimizzata e più funzionale rispetto alla query federata inversa 'id Wikidata in ICCD'

PREFIX lO: https://w3id.org/italia/onto/l0/ # Creo il prefisso per referenziare l'IRI della proprietà 'Descrizione' del sito dati.beniculturali.it

SELECT ?item ?itemLabel ?desc ?url WHERE { ?item wdt:P31 wd:Q33506 . # Recupera tutte le istanze di Musei ?item wdt:P131 wd:Q13369 . # Che appartengono all'area amministrativa di Rimini ?item wdt:P5782 ?id . # Recupera per ogni elemento l'Identificativo sul db unico Mibact BIND(URI(CONCAT("http://dati.beniculturali.it/mibact/luoghi/resource/CulturalInstituteOrSite/",?id)) AS ?url) # Crea l'URI relativo del service Beniculturali.it

SERVICE <http://dati.beniculturali.it/sparql> {
  ?url lO:description ?desc . # Recupera la descrizione degli Elementi tramite l'URI generato
}

SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }

}

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# Associo agli Elementi Wikidata (Musei) la corrispondente descrizione estesa presente nel db unico Mibact (beniculturali.it)
# Tramite id ICCD in Wikidata
# Query ottimizzata e più funzionale rispetto alla query federata inversa 'id Wikidata in ICCD'
PREFIX lO: <https://w3id.org/italia/onto/l0/>    # Creo il prefisso per referenziare l'IRI della proprietà 'Descrizione' del sito dati.beniculturali.it

SELECT ?item ?itemLabel ?desc ?url WHERE {
    ?item wdt:P31 wd:Q33506 .  # Recupera tutte le istanze di Musei
    ?item wdt:P131 wd:Q13369 . # Che appartengono all'area amministrativa di Rimini
    ?item wdt:P5782 ?id .      # Recupera per ogni elemento l'Identificativo sul db unico Mibact
    BIND(URI(CONCAT("http://dati.beniculturali.it/mibact/luoghi/resource/CulturalInstituteOrSite/",?id)) AS ?url)  # Crea l'URI relativo del service Beniculturali.it

    SERVICE <http://dati.beniculturali.it/sparql> {
      ?url lO:description ?desc . # Recupera la descrizione degli Elementi tramite l'URI generato
    } 

    SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
}

Query found at

• https://www.wikidata.org/wiki/Wikidata:Gruppo_Wikidata_per_Musei,_Archivi_e_Biblioteche/Query