query-c46c987768bdd446901c7d743819a634
(70) Timeline of position holders: members of the Politburo Standing Committee of the Chinese Communist PartyNo.70 (2022.10.23T0101 created)
Use at
- https://query.wikidata.org/sparql
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# title of the query
#title: timeline of members of the Politburo Standing Committee of the Chinese Communist Party
# viewed as timeline (also viewable as table and image grid)
#defaultView:Timeline
SELECT DISTINCT ?member ?memberLabel ?image ?start ?end
WHERE {
# ?member is instance of (P31) human (Q5)
?member wdt:P31 wd:Q5;
# ?member's "position held" (P39) statement is ?x_position
p:P39 ?x_position.
# ?x_position's value is "subclass of (P279)" [ZeroOrMorePath (*)]
# member of the Politburo Standing Committee of the Chinese Communist Party (Q42327067)
?x_position ps:P39/wdt:P279* wd:Q42327067
# optional: ?member's image (P18) is ?image
OPTIONAL {?member wdt:P18 ?image}
# optional: ?x_position's qualifier "start time" (P580) is ?start
OPTIONAL {?x_position pq:P580 ?start}
# optional: ?x_position's qualifier "end time" (P582) is ?end
OPTIONAL {?x_position pq:P582 ?end}
# show label in auto language as default, and English when no default label exists
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Query found at
- https://www.wikidata.org/wiki/User:Neo-Jay/Query
- https://www.wikidata.org/wiki/User:Neo-Jay/Query/1.1
graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
v5("?end"):::projected
v3("?image"):::projected
v1("?member"):::projected
v4("?start"):::projected
v2("?x_position")
a1((" "))
c11(["bd:serviceParam"]):::iri
c6(["wd:Q42327067"]):::iri
c2(["wd:Q5"]):::iri
c13(["#91;AUTO_LANGUAGE#93;,en"]):::literal
v1 --"p:direct/P31"--> c2
v1 --"p:P39"--> v2
v2 --"p:statement/P39"--> a1
a1 --"p:direct/P279"--> c6
subgraph optional0["(optional)"]
style optional0 fill:#bbf,stroke-dasharray: 5 5;
v1 -."p:direct/P18".-> v3
end
subgraph optional1["(optional)"]
style optional1 fill:#bbf,stroke-dasharray: 5 5;
v2 -."p:qualifier/P580".-> v4
end
subgraph optional2["(optional)"]
style optional2 fill:#bbf,stroke-dasharray: 5 5;
v2 -."p:qualifier/P582".-> v5
end
subgraph s1["http://wikiba.se/ontology#label"]
style s1 stroke-width:4px;
c11 --"wikibase:language"--> c13
end