query-c16f036437c6085ccf4e79b645b3ca3d

rq turtle/ttl

Communes avec arrondissements, départements et régions. Au 1er janvier 2015, il y avait 36 658 communes en France. SELECT ?insee ?commune ?nom ?inseeArrondissement ?arrondissement ?inseeDépartement ?département ?inseeRégion ?région WHERE { BIND ( "2015-01-01"^^xsd:dateTime as ?dateRecherche ) # Au 1er janvier 2015 ?commune p:P374 ?P374node . # existence d'un code Insee ?P374node ps:P374 ?insee . # valeur du code Insee OPTIONAL { ?P374node pq:P580 ?dateDébutCode . } # date de début du code Insee OPTIONAL { ?P374node pq:P582 ?dateFinCode . } # date de fin du code Insee FILTER ( !BOUND(?dateDébutCode) || ?dateDébutCode <= ?dateRecherche ) # ancien code Insee FILTER ( !BOUND(?dateFinCode) || ?dateFinCode > ?dateRecherche ) # futur code Insee { ?commune wdt:P31 wd:Q484170 . # nature de commune OPTIONAL { ?commune wdt:P571 ?dateCréation . } # date de création OPTIONAL { ?commune wdt:P576 ?dateDissolution . } # date de dissolution

?département wdt:P2586 ?inseeDépartement. # code Insee du département
?commune p:P131 ?P131nodeDépartement .
?P131nodeDépartement ps:P131 ?département .  # valeur du département
MINUS { ?P131nodeDépartement pq:P1013 wd:Q583865 . } # département collectivité
OPTIONAL { ?P131nodeDépartement pq:P580 ?dateDébutDépartement . } # date de début du département
OPTIONAL { ?P131nodeDépartement pq:P582 ?dateFinDépartement . } # date de fin du département

OPTIONAL { # pas d'arrondissements à Mayotte
?arrondissement wdt:P3423 ?inseeArrondissement. # code Insee de l'arrondissement
?commune p:P131 ?P131nodeArrondissement .
?P131nodeArrondissement ps:P131 ?arrondissement .  # valeur de l'arrondissement
OPTIONAL { ?P131nodeArrondissement pq:P580 ?dateDébutArrondissement . } # date de début de l'arrondissement
OPTIONAL { ?P131nodeArrondissement pq:P582 ?dateFinArrondissement . } # date de fin de l'arrondissement
  }

{ ?région wdt:P2585 ?inseeRégion. # code Insee de la région ?commune p:P131 ?P131nodeRégion . ?P131nodeRégion ps:P131 ?région . # valeur de la région } UNION { ?région wdt:P2585 ?inseeRégion. # code Insee de la région ?département p:P131 ?P131nodeRégion . ?P131nodeRégion ps:P131 ?région . # valeur de la région } OPTIONAL { ?P131nodeRégion pq:P580 ?dateDébutRégion . } # date de début de la région OPTIONAL { ?P131nodeRégion pq:P582 ?dateFinRégion . } # date de fin de la région

 }   
UNION { VALUES (?commune ?inseeDépartement ?inseeArrondissement ?inseeRégion ?région) {(wd:Q90 "75" "751" "11" wd:Q13917)} } # Paris

FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # communes futures
FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # communes passées
FILTER ( !BOUND(?dateDébutDépartement) || ?dateDébutDépartement <= ?dateRecherche ) # ancien département
FILTER ( !BOUND(?dateFinDépartement) || ?dateFinDépartement > ?dateRecherche ) # futur département 
FILTER ( !BOUND(?dateDébutArrondissement) || ?dateDébutArrondissement <= ?dateRecherche ) # ancien arrondissement
FILTER ( !BOUND(?dateFinArrondissement) || ?dateFinArrondissement > ?dateRecherche ) # futur arrondissement 
FILTER ( !BOUND(?dateDébutRégion) || ?dateDébutRégion <= ?dateRecherche ) # ancienne région
FILTER ( !BOUND(?dateFinRégion) || ?dateFinRégion > ?dateRecherche ) # future région

?commune p:P1448 ?P1448node . # existence d'un nom ?P1448node ps:P1448 ?nom . # valeur du nom FILTER( lang(?nom)="fr" ). # nom en français MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom } ORDER BY (?insee)

Use at

• https://query.wikidata.org/sparql

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
# Communes avec arrondissements, départements et régions. Au 1er janvier 2015, il y avait 36 658 communes en France.
SELECT ?insee ?commune ?nom ?inseeArrondissement ?arrondissement ?inseeDépartement ?département ?inseeRégion ?région
WHERE {
  BIND ( "2015-01-01"^^xsd:date as ?dateRecherche ) # Au 1er janvier 2015
  ?commune p:P374 ?P374node . # existence d'un code Insee
    ?P374node ps:P374 ?insee . # valeur du code Insee
    OPTIONAL { ?P374node pq:P580 ?dateDébutCode . } # date de début du code Insee
    OPTIONAL { ?P374node pq:P582 ?dateFinCode . } # date de fin du code Insee
    FILTER ( !BOUND(?dateDébutCode) || ?dateDébutCode <= ?dateRecherche ) # ancien code Insee
    FILTER ( !BOUND(?dateFinCode) || ?dateFinCode > ?dateRecherche ) # futur code Insee
  {
    ?commune wdt:P31 wd:Q484170 .  # nature de commune
    OPTIONAL { ?commune wdt:P571 ?dateCréation . } # date de création
    OPTIONAL { ?commune wdt:P576 ?dateDissolution . } # date de dissolution

    ?département wdt:P2586 ?inseeDépartement. # code Insee du département
    ?commune p:P131 ?P131nodeDépartement .
    ?P131nodeDépartement ps:P131 ?département .  # valeur du département
    MINUS { ?P131nodeDépartement pq:P1013 wd:Q583865 . } # département collectivité
    OPTIONAL { ?P131nodeDépartement pq:P580 ?dateDébutDépartement . } # date de début du département
    OPTIONAL { ?P131nodeDépartement pq:P582 ?dateFinDépartement . } # date de fin du département 

    OPTIONAL { # pas d'arrondissements à Mayotte
    ?arrondissement wdt:P3423 ?inseeArrondissement. # code Insee de l'arrondissement
    ?commune p:P131 ?P131nodeArrondissement .
    ?P131nodeArrondissement ps:P131 ?arrondissement .  # valeur de l'arrondissement
    OPTIONAL { ?P131nodeArrondissement pq:P580 ?dateDébutArrondissement . } # date de début de l'arrondissement
    OPTIONAL { ?P131nodeArrondissement pq:P582 ?dateFinArrondissement . } # date de fin de l'arrondissement
      }  

   { 
    ?région wdt:P2585 ?inseeRégion. # code Insee de la région
    ?commune p:P131 ?P131nodeRégion .
    ?P131nodeRégion ps:P131 ?région .  # valeur de la région
      }
    UNION { 
     ?région wdt:P2585 ?inseeRégion. # code Insee de la région
    ?département p:P131 ?P131nodeRégion . 
    ?P131nodeRégion ps:P131 ?région .  # valeur de la région
      }
    OPTIONAL { ?P131nodeRégion pq:P580 ?dateDébutRégion . } # date de début de la région
    OPTIONAL { ?P131nodeRégion pq:P582 ?dateFinRégion . } # date de fin de la région

     }   
    UNION { VALUES (?commune ?inseeDépartement ?inseeArrondissement ?inseeRégion ?région) {(wd:Q90 "75" "751" "11" wd:Q13917)} } # Paris 

    FILTER ( !BOUND(?dateCréation) || ?dateCréation <= ?dateRecherche ) # communes futures
    FILTER ( !BOUND(?dateDissolution) || ?dateDissolution > ?dateRecherche ) # communes passées
    FILTER ( !BOUND(?dateDébutDépartement) || ?dateDébutDépartement <= ?dateRecherche ) # ancien département
    FILTER ( !BOUND(?dateFinDépartement) || ?dateFinDépartement > ?dateRecherche ) # futur département 
    FILTER ( !BOUND(?dateDébutArrondissement) || ?dateDébutArrondissement <= ?dateRecherche ) # ancien arrondissement
    FILTER ( !BOUND(?dateFinArrondissement) || ?dateFinArrondissement > ?dateRecherche ) # futur arrondissement 
    FILTER ( !BOUND(?dateDébutRégion) || ?dateDébutRégion <= ?dateRecherche ) # ancienne région
    FILTER ( !BOUND(?dateFinRégion) || ?dateFinRégion > ?dateRecherche ) # future région 

  ?commune p:P1448 ?P1448node . # existence d'un nom
    ?P1448node ps:P1448 ?nom . # valeur du nom
    FILTER( lang(?nom)="fr" ). # nom en français
    MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
    OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
    OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom
    FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
    FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom
}
ORDER BY (?insee)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_France/Communes/Liste_des_communes_avec_les_divisions_administratives