query-c109f17a9a62dd0f874f718afb9bc857

rq turtle/ttl

SPARQL sandbox

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?sample ?sampleLabel ?property ?propertyLabel ?qualifiers ?statements WHERE {
  {
    SELECT DISTINCT ?p ?qualifiers (SAMPLE(?item) AS ?sample) (COUNT(?stmt) AS ?statements) WHERE {
      {
        SELECT ?item ?p ?stmt (GROUP_CONCAT(?kv) AS ?qualifiers) WHERE {
          {
            SELECT ?item ?p ?stmt ?str ?kv WHERE {
              {
                SELECT ?item ?p ?stmt ?str (COUNT(?qval) AS ?values) WHERE {
                  VALUES ?p {p:P1359}
                  ?item ?p ?stmt .
                  #?stmt pq:P642 ?qval0 .
                  ?stmt ?pq ?qval .
                  ?wdq wikibase:qualifier ?pq .
                  BIND(STRAFTER(STR(?pq), "/P") AS ?str)
                }
                GROUP BY ?item ?p ?stmt ?str
              }
              BIND(CONCAT(?str, ":", STR(?values)) AS ?kv)
            }
            ORDER BY DESC(STRLEN(?str)) DESC(?str) ?kv ?stmt ?p
          }
        }
        GROUP BY ?item ?p ?stmt
      }
    }
    GROUP BY ?p ?qualifiers
  }
  ?property wikibase:claim ?p .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?property DESC(?statements)

Query found at

• https://www.wikidata.org/wiki/User:SM5POR/Queries