query-bf9f44ecb3ff55b2332ad7f0c98cae50
Question image 21:03, 21 December 2022 (UTC)) talk (Weft ? Merci d'avance. [3]Bonjour Shonagon, peux-tu m'indiquer le problème avec cette image : J'ai vu passer quelques-unes de tes contributions. C'est vraiment remarquable. Bravo. Un exemple de requête pour avoir la liste des œuvres de l'exposition Le Nain : C'est quelquefois un choix difficile la sélection d'image. Il peut y avoir d'un côté une image de grande taille avec quelques défauts mais plutôt bonne et une image réduite mais de très bonne qualité dans la lumière ou les rendus des couleurs. On choisit souvent la grande image mais faut pas hésiter à choisir une image plus réduite si la qualité est nettement meilleure. Au final c'est très utile pour les réutilisations que nous fassions ces choix, par exemple pour les infobox des projets wikimedia ou les requêtes sur les données. L'usage de la consultation c'est d'abord d'avoir une seule image et un utilisateur qui souhaiterait voir plusieurs versions peut toujours aller sur Commons. où ma photo n'est vraiment pas bonne surtout en comparaison de l'autre qui est superbe). Il y a encore pas mal d'améliorations à faire sur les images.un exemple récentDe mon côté, il m'arrive souvent de remplacer des images par d'autres, que parfois j'ai prises moi-même. Je n'hésite pas non plus à virer aussi les images que j'ai faites et utilisées du wikidata ( . En fait la contrainte correspond à ce que tu décris mais la clarification indique que s'il y a plusieurs images c'est surtout la première image qui est utilisée et que pour d'autres images il vaut mieux utiliser d'autres propriétés. Donc s'il n'y a qu'une image c'est celle-ci qui est le plus souvent sera utilisée ; autant n'avoir qu'une image, estimée la meilleure. Il demeure bien sûr des cas où c'est intéressant d'avoir plusieurs images mais si ce n'est pas utile mieux vaut s'abstenir d'en rajouter. Ca pourrait être une bonne idée de s'appuyer sur le rang préféré pour l'image. Cependant la pratique actuelle de contribution n'y correspond pas, ça ne cadrerait pas avec les réutilisations qui ne prendrait que malgré tout la première et surtout ça serait ouvrir la boîte de Pandore pour du déversement massif inmaintenable et qui inonderait pas mal d'éléments ; ce qui explique l'usage, notamment pour les œuvres d'art, de n'avoir qu'une déclaration image.WeftBonjour 08:20, 22 December 2022 (UTC)) talk (WeftBonjour Shonagon, d'accord merci pour ces précisions, va falloir que j'adapte ma façon de faire car ce n'est pas ce que je faisais jusque-là, je suis encore un débutant sur Wikidata ;) je comprenais la restriction comme imposant de ne sélectionner qu'une seule valeur préférée ce que je faisais, par contre je mettais toutes les images de Commons... Merci pour la sollicitation du musée Picasso ! 21:31, 21 December 2022 (UTC)) talk (ShonagonPar ailleurs sur ce tableau, j'ai envoyé un message au musée Picasso car je ne trouve pas d'information sur l'affectation au département des peintures du Louvre et que l'œuvre n'est pas sur le site des Collections du Louvre. Peut-être que l'œuvre a été réaffactée depuis la publication de la notice Joconde, qui date de 2008. Bien à toi -- Q115787440#P373. Pour les peintures, c'est toujours mieux de n'avoir qu'une image, ne serait-ce que pour les réutilisations. C'est un des grands intérêts d'ailleurs de Wikidata par rapport à Commons, de justement présenter une image vedette. On peut toujours associer (et crééer si besoin) une catégorie Commons. C'est fait : contrainte de meilleure valeur unique a une (P18)image . La propriété WeftBonjour
Use at
- https://query.wikidata.org/sparql
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:ImageGrid
# Œuvres de l'exposition Le Mystère Le Nain
SELECT distinct ?item ?itemLabel
(GROUP_CONCAT(distinct ?crea_label; separator=" - ") as ?crea)
(GROUP_CONCAT(distinct ?date; separator=" ; ") as ?dates)
(CONCAT(STR(?hauteur),"×",STR(?largeur)," cm") AS ?dimensions)
(GROUP_CONCAT(distinct ?collLb; separator=" - ") as ?collection)
(GROUP_CONCAT(distinct ?ninv; separator=" - ") as ?inv)
(SAMPLE(?img) as ?image) # si plusieurs images, une est choisie au hasard
(SAMPLE(?url) as ?URL)
WHERE {
?item wdt:P608 wd:Q50314087.
OPTIONAL { ?item wdt:P170 ?crea.
?crea rdfs:label ?crea_label filter (lang(?crea_label) = "fr").}
OPTIONAL { ?item wdt:P18 ?img }
OPTIONAL { ?item wdt:P195 ?coll.
?coll rdfs:label ?collLb filter (lang(?collLb) = "fr")}
OPTIONAL { ?item wdt:P2048 ?hauteur }
OPTIONAL { ?item wdt:P2049 ?largeur }
OPTIONAL { ?item p:P571 ?declarationdate }
OPTIONAL { ?item wdt:P217 ?ninv }
OPTIONAL { MINUS {?declarationdate pq:P1319 ?pasavant }
MINUS {?declarationdate pq:P1480 wd:Q5727902 }
?declarationdate ps:P571 ?dateunique .
BIND (year(?dateunique) AS ?date)}
OPTIONAL { MINUS {?declarationdate pq:P1319 ?pasavant }
?declarationdate pq:P1480 wd:Q5727902.
?declarationdate ps:P571 ?dateunique .
BIND (CONCAT("c.",STR(year(?dateunique))) AS ?date)}
OPTIONAL { ?declarationdate pq:P1319 ?pasavant .
?declarationdate pq:P1326 ?pasapres.
BIND (CONCAT(STR(year(?pasavant)),"-",STR(year(?pasapres))) AS ?date)}
############ Trouver une URL vedette ############
### Cas n°1, une URL via un identifiant spécifique à la collection
OPTIONAL {
?item p:P195 ?declarationlcoll.
?declarationlcoll ps:P195 ?coll.
{?Qprop wdt:P2378 ?coll.}
UNION{
?coll wdt:P361 ?Topcoll.
?Qprop wdt:P2378 ?Topcoll.
}
?Qprop wdt:P31/wdt:P279* wd:Q18618644.
?Qprop wikibase:directClaim ?prop.
?item ?prop ?id .
?Qprop wdt:P1630 ?formatterurl .
BIND(IRI(REPLACE(?id, '^(.+)$', ?formatterurl)) AS ?urlColl)
}
### Cas n°2, une URL via la propriété P973/"décrit à l'URL"
OPTIONAL {
?item wdt:P973 ?urlP973.
}
### Cas n°3, une URL via une propriété identifant d'œuvre d'art
OPTIONAL {
?Qprop wikibase:directClaim ?prop.
?Qprop wdt:P31/wdt:P279* wd:Q18618644.
?item ?prop ?id .
?Qprop wdt:P1630 ?formatterurl .
BIND(IRI(REPLACE(?id, '^(.+)$', ?formatterurl)) AS ?urlID)
}
############ cas n°1 l'emporte sur cas n°2 qui l'emporte sur cas n°3 ############
BIND(COALESCE(COALESCE(?urlColl, ?urlP973),?urlID) AS ?url)
########################
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en"}
} GROUP BY ?item ?itemLabel ?hauteur ?largeur
ORDER BY xsd:integer(?numCatalogue)