query-bde5d1d543cd7037b0dca3f1cc638b72

rq turtle/ttl

Appendix IIB: Conserved and rejected names of families of bryophytes and spermatophytes (Q65682475)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wdno: <http://www.wikidata.org/prop/novalue/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?item ?taxonName ?nomenclaturalStatusLabel ?typeGenus ?typeGenusName ?typeSpeciesName ?typeSpeciesRoleLabel WHERE {
      ?item wdt:P105 wd:Q35409 . # family
      ?item p:P225 ?taxonNameStatement .
      ?taxonNameStatement ps:P225 ?taxonName .
      ?taxonNameStatement pq:P1135 ?nomenclaturalStatus . 
      ?taxonNameStatement prov:wasDerivedFrom ?ref .
      ?ref pr:P248 wd:Q65682475 . # Appendix IIB
      OPTIONAL {?item wdt:P427 ?typeGenus} .
      OPTIONAL {?item wdt:P427/wdt:P225 ?typeGenusName} .
      OPTIONAL {?typeGenus wdt:P427 ?typeSpecies} .
      OPTIONAL {?typeGenus wdt:P427/wdt:P225 ?typeSpeciesName} .
      OPTIONAL {?typeGenus p:P427/pq:P3831 ?typeSpeciesRole} . 
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
      #FILTER(!bound(?typeSpecies))
      #MINUS {?typeGenus rdf:type wdno:P427} 
}
ORDER BY ASC(?taxonName)

Query found at

• https://www.wikidata.org/wiki/User:Succu/SPARQL