query-b6abd0a42d0a2e537c8f21d0d23ed29c

rq turtle/ttl

Propertiesinstance of (P31)subclass of (P279)applies to jurisdiction (P1001)position held (P39)start time (P580)end time (P582)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?country ?countryLabel ?office ?officeLabel ?person ?personLabel
WHERE {    
  ?country wdt:P31 wd:Q185441 .            # for all EU member states
  OPTIONAL {
    ?office wdt:P279* wd:Q4018482 ;        #   find any subclass of "finance minister"
            wdt:P1001 ?country .           #   with that jurisdiction
    OPTIONAL {
      ?person p:P39 ?posn ; wdt:P31 wd:Q5 .  # find all humans with a position
      ?posn ps:P39 ?office ;                 # of that office
            pq:P580 ?start_date .            # where the position statement has a start date
      OPTIONAL { ?posn pq:P582 ?end_date }  # but with no end date
      FILTER ( !bound(?end_date) || isBLANK(?end_date) ) . 
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
ORDER BY ?countryLabel ?officeLabel

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2017/06