query-b3e5666dc2a5a16481aab1fa2325cbd1

rq turtle/ttl

Related roles

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX target1: <http://www.wikidata.org/entity/Q6053150>
PREFIX target2: <http://www.wikidata.org/entity/Q125207931>

SELECT
  ?persons

  ?role ?roleLabel

  ?other_event_series ?other_event_seriesLabel
  (CONCAT("#scientificeventseries/", SUBSTR(STR(?other_event_series), 32)) AS ?other_event_seriesUrl)

  ?example_person ?example_personLabel
  (CONCAT("#author/", SUBSTR(STR(?example_person), 32)) AS ?example_personUrl)


WHERE {
   {
  SELECT 
    (COUNT(DISTINCT ?person) AS ?persons)
    ?other_event_series
    ?role
    (SAMPLE(?person) AS ?example_person)
  WHERE {
    ?event wdt:P179 target1: ;
           p:P664 ?organizer_statement .
    ?organizer_statement ps:P664 ?person ;
                          pq:P3831 target2: .

    [] wdt:P179 ?other_event_series ;
       p:P664 ?other_organizer_statement .
    ?other_organizer_statement ps:P664 ?person ;
                               pq:P3831 ?role .
    FILTER (target2: != ?role)
  }
  GROUP BY ?other_event_series ?role
}  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?persons)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Synia:scientificeventseries-organizationalrole