query-b2fc0e1eb6c62c193d2c71ed398c6bb0

rq turtle/ttl

Next, I calculated which senators were the first to serve in each seat for each congressional session.

Use at

• https://query.wikidata.org/sparql

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?sen ?senLabel ?district ?districtLabel ?term ?termNum WHERE {
  {
    SELECT ?district ?term (MIN(?start) AS ?first) WHERE {
      ?sen p:P39 ?ps.
      ?ps ps:P39 wd:Q4416090;
        pq:P2937 ?term;
        pq:P768 ?district;
        pq:P580 ?start.
      FILTER ( ?start > "1913"^^xsd:dateTime )
    }
    GROUP BY ?district ?term
  }
  ?sen p:P39 ?ps.
  ?ps ps:P39 wd:Q4416090;
    pq:P2937 ?term;
    pq:P768 ?district;
    pq:P580 ?first.
  ?term (p:P31/pq:P1545) ?termNum.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY (?district) (xsd:integer(?termNum))

Query found at

• https://www.wikidata.org/wiki/Wikidata_talk:WikiProject_every_politician/United_States_of_America