query-b2d1f6e1eb20432978b0609b839070bf

rq turtle/ttl

Collapsing query ). https://w.wiki/5jBW , especially when used with a map-plotting query like https://w.wiki/5jC5 mileage measured along the track. It can be quite helpful in finding stations with the wrong coordinates. (As also is the query's big brother (P6710)linear reference Here's a query to compare how apart stations are from a particular station according to their coordinates, compared to how far they are apart according to a

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT  ?ratio  ?item2 ?item2Label ?dist ?mileage_diff ?section ?lin ?lin2 ?sectionLabel 


WHERE { 
  VALUES ?item {wd:Q2525068} .
   {
  SELECT ?item ?section ?elr ?lin ?itemLoc WHERE {
    ?item p:P795 ?stmt .
    ?stmt ps:P795 ?section . 
    ?section wdt:P10271 ?elr .
    ?stmt pq:P6710 ?lin .
    ?item wdt:P625 ?itemLoc .
  }
}.
  ?item2 wdt:P795 ?section .
  FILTER (?item != ?item2) .
  {
    SELECT (?item AS ?item2) ?section (?lin AS ?lin2) (?itemLoc AS ?item2Loc) WHERE {
       {
  SELECT ?item ?section ?elr ?lin ?itemLoc WHERE {
    ?item p:P795 ?stmt .
    ?stmt ps:P795 ?section . 
    ?section wdt:P10271 ?elr .
    ?stmt pq:P6710 ?lin .
    ?item wdt:P625 ?itemLoc .
  }
}.
    }
  }
  BIND ((geof:distance(?itemLoc, ?item2Loc) / 1.609) AS ?dist) .
  BIND (abs(?lin - ?lin2) AS ?mileage_diff) . 
  BIND (?dist / ?mileage_diff AS ?ratio) . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } .
} 
ORDER BY ?lin2

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2022/09