query-b1758f0168c11707dc3130fa395800a4
École primaireDéfinitions : Une école primaire est : soit un établissement comprenant à la fois des classes de niveau maternel et de niveau élémentaire. soit une école maternelle et/ou une école élémentaire, c'est-à-dire n'importe quelle école du premier degré,
Use at
- https://query.wikidata.org/sparql
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
SELECT DISTINCT ?établissement ?nom ?code_UAI WHERE {
BIND ( "2024-09-01"^^xsd:date as ?dateRecherche ) # Au 1er septembre 2024
?établissement wdt:P3202 ?code_UAI. # code_UAI
?établissement wdt:P7374 ?niveau.
VALUES ?niveau { wd:Q273556 wd:Q3578542 } # classes de niveau maternel ou élémentaire
?établissement p:P1448 ?P1448node . # existence d'un nom
?P1448node ps:P1448 ?nom . # valeur du nom
FILTER( lang(?nom)="fr" ). # nom en français
MINUS { ?P1448node pq:P2241 ?dépréciationNom . } # nom erroné
OPTIONAL { ?P1448node pq:P580 ?dateDébutNom . } # date de début du nom
OPTIONAL { ?P1448node pq:P582 ?dateFinNom . } # date de fin du nom
FILTER ( !BOUND(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche ) # ancien nom
FILTER ( !BOUND(?dateFinNom) || ?dateFinNom > ?dateRecherche ) # futur nom
}
ORDER BY ?code_UAI
Query found at
graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
v8("?P1448node")
v1("?code_UAI"):::projected
v4("?dateDébutNom")
v2("?dateFinNom")
v6("?dateRecherche")
v9("?dépréciationNom")
v8("?niveau")
v5("?nom"):::projected
v6("?établissement"):::projected
f0[["(not bound(?dateFinNom) || ?dateFinNom > ?dateRecherche)"]]
f0 --> v2
f0 --> v6
f1[["(not bound(?dateDébutNom) || ?dateDébutNom <= ?dateRecherche)"]]
f1 --> v4
f1 --> v6
f2[["?nom = 'fr'"]]
f2 --> v5
bind3[/"'2024-09-01^^xsd:date'"/]
bind3 --as--o v6
v6 --"p:direct/P3202"--> v1
v6 --"p:direct/P7374"--> v8
bind4[/VALUES ?niveau/]
bind4-->v8
bind40(["wd:Q273556"])
bind40 --> bind4
bind41(["wd:Q3578542"])
bind41 --> bind4
v6 --"p:P1448"--> v8
v8 --"p:statement/P1448"--> v5
subgraph minus5["MINUS"]
style minus5 stroke-width:6px,fill:pink,stroke:red;
v8 --"p:qualifier/P2241"--> v9
end
subgraph optional0["(optional)"]
style optional0 fill:#bbf,stroke-dasharray: 5 5;
v8 -."p:qualifier/P580".-> v4
end
subgraph optional1["(optional)"]
style optional1 fill:#bbf,stroke-dasharray: 5 5;
v8 -."p:qualifier/P582".-> v2
end