query-ad845d31e0b231782f7fcb28c472e4dd

rq turtle/ttl

Items without geolocation ordered by presence in Wikimedia projects (e.g. n. of Wikipedia pages)

authors: Valerio_Bozzolan, Yiyi

license: CC0

date: 2022

SELECT ?item ?itemLabel ?instanceFilterLabel ?areaLabel ?links WHERE { { SELECT ?item (SAMPLE(?instanceFilter) AS ?instanceFilter) (COUNT(?link) AS ?links) WHERE {

# apply territory filter (Milano)
?item (wdt:P131*) wd:Q490.

# item must be an instance of (of any subclass of) something we want
?item wdt:P31/wdt:P279* ?instanceFilter.
VALUES (?instanceFilter) {
    # educational institution
    (wd:Q2385804)

    # park
    (wd:Q22698)
}

# exclude items with coordinates or an headquarter or that are deprecated
MINUS {
  ?item wdt:P625|wdt:P159|wdt:P576 ?unusedinfo.
}

#OPTIONAL {
# links to Wikimedia projects
  ?link schema:about ?item.
#}

} # group by item so we can count their links GROUP BY ?item

ORDER BY DESC(?links)

LIMIT 100 }

# allow to read the area (subset of area filter) ?item wdt:P131 ?area.

# apply labels after aggregation SERVICE wikibase:label { bd:serviceParam wikibase:language "en,it,es,fr,de,pt" . } }

ORDER BY DESC(?links)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# Items without geolocation ordered by presence in Wikimedia projects (e.g. n. of Wikipedia pages)
#
# authors: Valerio_Bozzolan, Yiyi
# license: CC0
# date: 2022

SELECT ?item ?itemLabel ?instanceFilterLabel ?areaLabel ?links WHERE { {
  SELECT ?item (SAMPLE(?instanceFilter) AS ?instanceFilter) (COUNT(?link) AS ?links) WHERE {

    # apply territory filter (Milano)
    ?item (wdt:P131*) wd:Q490.

    # item must be an instance of (of any subclass of) something we want
    ?item wdt:P31/wdt:P279* ?instanceFilter.
    VALUES (?instanceFilter) {
        # educational institution
        (wd:Q2385804)

        # park
        (wd:Q22698)
    }

    # exclude items with coordinates or an headquarter or that are deprecated
    MINUS {
      ?item wdt:P625|wdt:P159|wdt:P576 ?unusedinfo.
    } 

    #OPTIONAL {
    # links to Wikimedia projects
      ?link schema:about ?item.
    #}
  }
  # group by item so we can count their links
  GROUP BY ?item

  ORDER BY DESC(?links)

  LIMIT 100
 }

 # allow to read the area (subset of area filter)
 ?item wdt:P131 ?area.

 # apply labels after aggregation
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,it,es,fr,de,pt" . }
}

ORDER BY DESC(?links)

Query found at

• https://www.wikidata.org/wiki/User:Valerio_Bozzolan/Museum_and_parks_without_coordinates_somewhere.sparql