query-ac915d9c366d1a063affd65c2105b48d

rq turtle/ttl

Map and list of municipalities in The NetherlandsBased on the SPARQL query example Replace Q1075310 by a boat class to get a map of that boat class. Map of sailboats home ports Map and list of municipalities in The NetherlandsBased on the SPARQL query example Replace Q1075310 by a boat class to get a map of that boat class.

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#Map of all sailboat (Q1075310) home ports (P504)
#boat = wikidata item id (qid)
#home_portLabel = home port name
#home_port_coord = home port coordinates
#boatLabel = wikidata item name
#boat_name (optional) = boat name
#image (optional) = picture

#defaultView:Map
SELECT DISTINCT ?boat ?boatLabel ?boat_name ?instance_ofLabel ?home_portLabel ?image ?home_port_coord WHERE {
  ?boat wdt:P31/wdt:P279* wd:Q1075310; #'?boat' are 'instance of'(P31) and any number of 'subclass of' (P279*) of 'sailboat'(Q1075310)
        wdt:P31 ?instance_of; #'?boat' 'instance of' (P31) are '?instance_of'
        wdt:P504 ?home_port . #'?boat' 'home port' (P504) are '?home_port'
  #filter out home ports that are no longer current (home port (P504) with an 'end time' qualifier (P582))
  ?boat p:P504 ?statement1 .
  ?statement1 ps:P504 ?home_port .
  FILTER NOT EXISTS { ?statement1 pq:P582 ?x }
  ?home_port wdt:P625 ?home_port_coord. #'?home_port' 'coordinate location' (P625) are '?home_port_coord'

  OPTIONAL { ?boat wdt:P18 ?image . } 

  #'?boat" 'short name' (P1813) are '?boat_name'
  #filter out names that are no longer current (short name (P1813) with an 'end time' qualifier (P582))
  OPTIONAL {
    ?boat wdt:P1813 ?boat_name.
    ?boat p:P1813 ?statement2 .
    ?statement2 ps:P1813 ?boat_name .
    FILTER NOT EXISTS { ?statement2 pq:P582 ?x } 
  }  

  #xxxLabel is the label for any variable called xxx
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Sailing/Items
• https://www.wikidata.org/wiki/Wikidata:WikiProject_Sailing/Queries
• https://www.wikidata.org/wiki/Wikidata:WikiProject_Sailing/Queries/Map_of_sailboats_home_ports