query-a9a98dcfdd2ea84287012510e93518f2

rq turtle/ttl

MPs who have sat in twelve or more terms SELECT distinct ?terms ?mp ?mpLabel ?article WHERE { { SELECT ?mp (COUNT (distinct ?position) AS ?terms) WHERE { ?position wdt:P279 wd:Q16707842. # every UK MP (currently post-1832) ?mp p:P39 ?positionStatement . ?positionStatement ps:P39 ?position . } GROUP BY ?mp } optional { ?article schema:about ?mp . ?article schema:inLanguage "en" . ?article schema:isPartOf https://en.wikipedia.org/ . } SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } filter (?terms >= 12 ) . # twelve or more terms }
ORDER BY desc(?terms)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# MPs who have sat in twelve or more terms
SELECT distinct ?terms ?mp ?mpLabel ?article
WHERE
{
  {
    SELECT ?mp (COUNT (distinct ?position) AS ?terms) WHERE {
      ?position wdt:P279 wd:Q16707842. # every UK MP (currently post-1832)
      ?mp p:P39 ?positionStatement . ?positionStatement ps:P39 ?position . 
    }
    GROUP BY ?mp
  }
  optional { ?article schema:about ?mp . ?article schema:inLanguage "en" .
             ?article schema:isPartOf <https://en.wikipedia.org/> . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  filter (?terms >= 12 ) . # twelve or more terms
}   
ORDER BY desc(?terms)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_British_Politicians/Sample_Queries