query-a804e14f4e9ab2752732b2c5b66315ec

rq turtle/ttl

Propertiesmaintained by WikiProject (P6104)author name string (P2093)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Table
SELECT ?count ?authornamestring ?sample_pub ?sample_pubLabel
  (CONCAT(
      'https://tools.wmflabs.org/author-disambiguator/names_oauth.php?name=',
      ENCODE_FOR_URI(?authornamestring)) AS ?generic_resolver_url)
  (CONCAT(
      'https://author-disambiguator.toolforge.org/names_oauth.php?doit=Look+for+author&limit=5000&filter=wdt%3AP6104+wd%3AQ56241615&name=',
      ENCODE_FOR_URI(?authornamestring)) AS ?specific_resolver_url)
WHERE {
   {
  SELECT (count(DISTINCT ?work) as ?count) ?authornamestring (SAMPLE(?work) AS ?sample_pub) WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P2093 ?authornamestring .
  }
  GROUP BY ?authornamestring
  ORDER BY DESC(?count)
  LIMIT 200
}  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
}
ORDER BY DESC(?count)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Invasion_biology