query-a7cc2b2609435bd775cae81ad3e10eb1

rq turtle/ttl

List of all plates, all volumes, with their depecited plants, their historical and modern botanical (scientific) and Dutch (trivial) names, and Dutch Wikipedia articles about the plants. SELECT DISTINCT ?volume ?volumeLabel ?plate ?plateLabel ?plateImage ?plantDecpicted ?scientificNameInFB ?dutchTrivialNameInFB ?scientificNameModern ?dutchTrivialNameModern ?plantDecpictedWikipediaNL WHERE { wd:Q117860156 wdt:P527 ?volume. ?volume wdt:P527 ?plate. OPTIONAL{?plate wdt:P18 ?plateImage.}

?plate wdt:P1476 ?scientificNameInFB. FILTER(lang(?scientificNameInFB)='la') ?plate wdt:P1476 ?dutchTrivialNameInFB. FILTER(lang(?dutchTrivialNameInFB)='nl')

?plate wdt:P180 ?plantDecpicted. ?plantDecpicted rdfs:label ?scientificNameModern . FILTER(lang(?scientificNameModern)='la') ?plantDecpicted rdfs:label?dutchTrivialNameModern . FILTER(lang(?dutchTrivialNameModern)='nl')

OPTIONAL{?plantDecpictedWikipediaNL schema:about ?plantDecpicted; schema:isPartOf https://nl.wikipedia.org/.}

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". } } ORDER BY ?volumeLabel ?plateLabel

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
# List of all plates, all volumes, with their depecited plants, their historical and modern botanical (scientific) and Dutch (trivial) names, and Dutch Wikipedia articles about the plants.
SELECT DISTINCT 
?volume ?volumeLabel 
?plate ?plateLabel ?plateImage
?plantDecpicted
?scientificNameInFB ?dutchTrivialNameInFB ?scientificNameModern ?dutchTrivialNameModern
?plantDecpictedWikipediaNL
WHERE 
{
  wd:Q117860156 wdt:P527 ?volume.
  ?volume wdt:P527 ?plate.
  OPTIONAL{?plate wdt:P18 ?plateImage.}

  ?plate wdt:P1476 ?scientificNameInFB. FILTER(lang(?scientificNameInFB)='la')
  ?plate wdt:P1476 ?dutchTrivialNameInFB. FILTER(lang(?dutchTrivialNameInFB)='nl')

  ?plate wdt:P180 ?plantDecpicted.
  ?plantDecpicted rdfs:label ?scientificNameModern . FILTER(lang(?scientificNameModern)='la')
  ?plantDecpicted rdfs:label?dutchTrivialNameModern . FILTER(lang(?dutchTrivialNameModern)='nl')

  OPTIONAL{?plantDecpictedWikipediaNL schema:about ?plantDecpicted; 
           schema:isPartOf <https://nl.wikipedia.org/>.}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". } 
}
ORDER BY ?volumeLabel ?plateLabel

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Collection_highlights_National_Library_of_the_Netherlands/Flora_Batava/Queries