query-9901b37e842982c77f7d06fe4a7b5f1f

rq turtle/ttl

. This query is just on the edge of timing out (it took 59s when I ran it just now, and that's with the elections throttled back to only "since 1990": (Q741182)dissolution of parliament :(P1534)end cause their term there ended with and. In other words, they were elected for Term N, but they also were in office during Term N-1, until Parliament was dissolved for the electionThis is a straightforward query and it takes just a few seconds. However, I'd also like to write one which finds people who were in office

Use at

• https://query.wikidata.org/sparql

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT distinct ?election ?electionLabel ?members ?veterans ?held_at_dissolution where
{
  { SELECT distinct ?election ?electiondate where 
    { ?election wdt:P31 wd:Q15283424 . ?election wdt:P585 ?electiondate . 
    filter (?electiondate >= "1990-01-01T00:00:00Z"^^xsd:dateTime) } # throttle to post-1990
  } # find all general elections and their date (for sorting)

  { SELECT ?election (count(distinct ?item) as ?members) where 
    { ?item p:P39 ?positionStatement . ?positionStatement ps:P39 ?membership . 
      ?membership wdt:P2715 ?election . ?positionStatement pq:P2715 ?election .
    } group by ?election
  } # number of people elected in this election
    # this code finds anyone who served the parliamentary term linked to this election
    # with a P39 value which started with this election

  { SELECT ?election (count(distinct ?item) as ?veterans) where 
    { ?item p:P39 ?positionStatement . ?positionStatement ps:P39 ?membership . 
      ?membership wdt:P2715 ?election . ?positionStatement pq:P2715 ?election . 
     # item holds a term which began with the election
      ?item p:P39 ?positionStatement2 . ?positionStatement2 ps:P39 ?membership2 . 
      ?positionStatement2 pq:P580 ?start . filter ( ?start < ?electiondate ) .
      ?membership2 wdt:P279 wd:Q16707842 . ?election wdt:P585 ?electiondate .
     # item also holds another term which began before the election
     # and, critically, was an MP!
    } group by ?election
  } # people who served in any previous term

  { SELECT ?election (count(distinct ?item) as ?held_at_dissolution) where 
    { ?item p:P39 ?positionStatement . ?positionStatement ps:P39 ?membership . 
      ?membership wdt:P2715 ?election . ?positionStatement pq:P2715 ?election . 
     # item holds a term which began with the election
      ?membership wdt:P155 ?membership2 .
     # find the term which preceded that one
      ?item p:P39 ?positionStatement2 . ?positionStatement2 ps:P39 ?membership2 . 
     # find all items which hold that term
      ?positionStatement2 pq:P1534 wd:Q741182
     # and made it to dissolution
    } group by ?election
  } # people who served up to dissolution of the previous term

  SERVICE wikibase:label { bd:serviceParam wikibase:language 'en' }
} order by desc(?electiondate)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2018/08