query-97fa13fa3a34245485d02f7f46e57d7f

rq turtle/ttl

Drama schools by number of students on Wikidata

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX pr: <http://www.wikidata.org/prop/reference/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Map
# Drama schools by number of students on Wikidata
SELECT ?school ?schoolLabel ?website ?coords ?students ?sourcedStudents (FLOOR(?sourcedStudents/?students*10000)/100 AS ?layer) WHERE {
  # Total number of students on Wikidata
  {
    SELECT ?school (COUNT(?student) AS ?students) WHERE {
      ?school wdt:P31/wdt:P279* wd:Q2143781 .

      ?student wdt:P31 wd:Q5 . 
      ?student wdt:P69 ?school .
    } GROUP BY ?school ?schoolLabel
  }

  # Number of students with URL reference on Wikidata
  OPTIONAL {
    SELECT ?school (COUNT(?student) AS ?sourcedStudents) WHERE {
      ?school wdt:P31/wdt:P279* wd:Q2143781 .

      ?student wdt:P31 wd:Q5 . 
      ?student p:P69 ?schoolStatement .
      ?schoolStatement ps:P69 ?school .
      ?schoolStatement prov:wasDerivedFrom ?ref .
      ?ref pr:P854 ?url .

    } GROUP BY ?school ?schoolLabel ORDER BY DESC(?students)
  }

  # Some other useful data
  OPTIONAL { ?school wdt:P856 ?website . }
  OPTIONAL { ?school wdt:P625 ?coords . }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} ORDER BY DESC(?students)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Theatre/Queries