query-93c81b4b3f7bd60a6da62c8d3813fd82

rq turtle/ttl

Bouzinac

Use at

• https://query.wikidata.org/sparql

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
SELECT ?letter ?count (?count / ?total * 100 AS ?pct)
WHERE
{

{
  SELECT ?letter (COUNT(*) AS ?count)
  WHERE
  {
    ?item wdt:P31 wd:Q5 . # Humans
    ?item wdt:P27 wd:Q38 . # Italians
   # ?item wdt:P21 wd:Q6581097 . # male
    ?item wdt:P21 wd:Q6581072 . # female
    ?item p:P735 ?name_statement . # Given name
    ?name_statement ps:P735 / wdt:P1705 ?name . # Native label for name
    OPTIONAL { ?name_statement pq:P1545 ?ordinal . }
    FILTER (! BOUND(?ordinal) || ?ordinal = "1") # Use the only name (no ordinal value) or name #1
    BIND (SUBSTR(STR(?name), STRLEN(?name)) AS ?letter)
  }
  GROUP BY ?letter
}  
{
  SELECT (SUM(?count) AS ?total)
  WHERE
  {

{
  SELECT ?letter (COUNT(*) AS ?count)
  WHERE
  {
    ?item wdt:P31 wd:Q5 . # Humans
    ?item wdt:P27 wd:Q38 . # Italians
   # ?item wdt:P21 wd:Q6581097 . # male
    ?item wdt:P21 wd:Q6581072 . # female
    ?item p:P735 ?name_statement . # Given name
    ?name_statement ps:P735 / wdt:P1705 ?name . # Native label for name
    OPTIONAL { ?name_statement pq:P1545 ?ordinal . }
    FILTER (! BOUND(?ordinal) || ?ordinal = "1") # Use the only name (no ordinal value) or name #1
    BIND (SUBSTR(STR(?name), STRLEN(?name)) AS ?letter)
  }
  GROUP BY ?letter
}  }
}}
ORDER BY DESC(?count)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2020/09