query-928270b64b0eff80f23c61a2d120a8a5

rq turtle/ttl

title: List of properties which have instances or subclass of humans as possible value with male and female form in French SELECT ?property ?propertyLabel ?maleform ?femaleform (GROUP_CONCAT(?alias; SEPARATOR = ", ") AS ?aliases) WHERE { ?property p:P2302 ?statement. ?statement ps:P2302 wd:Q21510865; pq:P2308 wd:Q5; pq:P2309 ?relation. ?property rdfs:label ?propertyLabel. OPTIONAL { ?property skos:altLabel ?alias. FILTER((LANG(?alias)) = "fr") } FILTER((LANG(?propertyLabel)) = "fr") OPTIONAL { ?property wdt:P2521 ?femaleform. FILTER((LANG(?femaleform)) = "fr") } OPTIONAL { ?property wdt:P3321 ?maleform. FILTER((LANG(?maleform)) = "fr") } } GROUP BY ?property ?propertyLabel ?maleform ?femaleform

Use at

• https://query.wikidata.org/sparql

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
#title: List of properties which have instances or subclass of humans as possible value with male and female form in French
SELECT ?property ?propertyLabel ?maleform ?femaleform (GROUP_CONCAT(?alias; SEPARATOR = ", ") AS ?aliases) WHERE {
  ?property p:P2302 ?statement.
  ?statement ps:P2302 wd:Q21510865;
    pq:P2308 wd:Q5;
    pq:P2309 ?relation.
  ?property rdfs:label ?propertyLabel.
  OPTIONAL {
    ?property skos:altLabel ?alias.
    FILTER((LANG(?alias)) = "fr")
  }
  FILTER((LANG(?propertyLabel)) = "fr")
  OPTIONAL {
    ?property wdt:P2521 ?femaleform.
    FILTER((LANG(?femaleform)) = "fr")
  }
  OPTIONAL {
    ?property wdt:P3321 ?maleform.
    FILTER((LANG(?maleform)) = "fr")
  }
}
GROUP BY ?property ?propertyLabel ?maleform ?femaleform

Query found at

• https://www.wikidata.org/w/index.php?title=Topic:Wxxfud2aubxfa6q7&topic_showPostId=wxz71qqmbt3bhfw5#flow-post-wxz71qqmbt3bhfw5
• https://www.wikidata.org/wiki/Topic:Wxxfud2aubxfa6q7
• https://www.wikidata.org/wiki/Wikidata:Requests_for_comment/How_to_avoid_to_use_male_form_as_a_generic_form_in_property_labels_in_French%3F