query-91d2b5fa1f1b3e49ed9cacf204a1877f

rq turtle/ttl

Dataset of cities of Ukraine, suitable for import in GIS software

Author: [[User:Valerio Bozzolan]]

Date: 2023-10-05

License: CC0

SELECT DISTINCT ?city ?cityLabel ?cityLocation ?administrative ?administrativeLabel ?country WHERE {

# Force to Ukraine # (Explicit here so you can easily do the same for other countries) BIND(wd:Q212 AS ?country)

?city wdt:P31/wdt:P279* wd:Q515. ?city wdt:P17 ?country . ?city wdt:P625 ?cityLocation . ?city wdt:P17 ?country. ?city wdt:P131 ?administrative. ?administrative p:P31 ?administrativeInstanceOf;

# Exclude former cities. MINUS { ?city wdt:P31/wdt:P279* wd:Q22674925. }

# Excludes administratives with end time MINUS { ?administrativeInstanceOf pq:P582 ?administrativeEndTime. }

# Exclude administratives that are abolished. MINUS { ?administrative wdt:P576 ?administrativeAbolishedDate. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "uk,en" . } } ORDER BY DESC(?administrativeLabel) DESC(?cityLabel)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# Dataset of cities of Ukraine, suitable for import in GIS software
# Author: [[User:Valerio Bozzolan]]
# Date: 2023-10-05
# License: CC0
SELECT DISTINCT ?city ?cityLabel ?cityLocation ?administrative  ?administrativeLabel ?country WHERE {

  # Force to Ukraine
  # (Explicit here so you can easily do the same for other countries)
  BIND(wd:Q212 AS ?country)

  ?city wdt:P31/wdt:P279* wd:Q515.
  ?city wdt:P17 ?country .
  ?city wdt:P625 ?cityLocation .
  ?city wdt:P17 ?country.
  ?city wdt:P131 ?administrative.
  ?administrative p:P31 ?administrativeInstanceOf;

  # Exclude former cities.
  MINUS {
     ?city wdt:P31/wdt:P279* wd:Q22674925. 
  }

  # Excludes administratives with end time
  MINUS {
    ?administrativeInstanceOf pq:P582 ?administrativeEndTime.
  }

  # Exclude administratives that are abolished.
  MINUS {
    ?administrative wdt:P576 ?administrativeAbolishedDate. 
  }

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "uk,en" .
  }
}
ORDER BY DESC(?administrativeLabel) DESC(?cityLabel)

Query found at

• https://www.wikidata.org/wiki/Wikidata_talk:WikiProject_Ukraine