query-91b52d4bbeb46bcd4aeaaa25abde5cb2

rq turtle/ttl

Straßenkarte zur Wartung der Eigenschaft "physisch verbunden mit"

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX psv: <http://www.wikidata.org/prop/statement/value/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Map;Table
#------------------------------------------------------------------------------------
# Straßenkarte zur Wartung der Eigenschaft "physisch verbunden mit"
#------------------------------------------------------------------------------------

SELECT  ?item ?itemLabel ?coord ?line 

#########################################

#########################################


#########################################

WHERE {
  # jetzt Punkte und Linien für Ausgabe auf Karte ausgeben
 {  {
    SELECT ?item  ?coord #("9B0058" as ?rgb) 
    WHERE {
        ?item wdt:P131 wd:Q1731 .      # Objekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
        VALUES ?instance_of { 
            wd:Q34442      # Straße
            wd:Q79007      # Innerortstraße
            wd:Q21000333   # Einkaufsstraße 
            wd:Q174782     # Platz
            wd:Q537127     # Straßenbrücke
            wd:Q3397519    # Spannbetonbrücke 
            wd:Q1055465    # Balkenbrücke  
        } 
        ?item wdt:P31 ?instance_of .   # Objekt ist eine Instanz von Verkehrsobjekt (Straße, Platz,...)
        ?item wdt:P625 ?coord .        # Objekt hat Koordinate
    }
}}
 union
 {  {
    # Linien generieren 
    SELECT ?line #("009b0d" as ?rgb) 
    WHERE {
         {
    SELECT ?item  ?coord #("9B0058" as ?rgb) 
    WHERE {
        ?item wdt:P131 wd:Q1731 .      # Objekt liegt in Verwaltungseinheit Dresden (oder Subklasse)
        VALUES ?instance_of { 
            wd:Q34442      # Straße
            wd:Q79007      # Innerortstraße
            wd:Q21000333   # Einkaufsstraße 
            wd:Q174782     # Platz
            wd:Q537127     # Straßenbrücke
            wd:Q3397519    # Spannbetonbrücke 
            wd:Q1055465    # Balkenbrücke  
        } 
        ?item wdt:P31 ?instance_of .   # Objekt ist eine Instanz von Verkehrsobjekt (Straße, Platz,...)
        ?item wdt:P625 ?coord .        # Objekt hat Koordinate
    }
}.               # Gefundenen Punkte von oberen Abfrage übernehmen
        ?item wdt:P2789 ?item2 .        # Objekt1 ist physisch verbunden mit Objekt2
        ?item2 wdt:P625 ?coord2 .       # Objekt2 hat Koordinate

        # Koordinate von Objekt1 auseinander nehmen
        OPTIONAL{?item p:P625 / psv:P625 / wikibase:geoLatitude ?lat1 . }
        OPTIONAL{?item p:P625 / psv:P625 / wikibase:geoLongitude ?lon1 . }

        # Koordinate von Objekt2 auseinander nehmen 
        OPTIONAL{?item2 p:P625 / psv:P625 / wikibase:geoLatitude ?lat2 . }
        OPTIONAL{?item2 p:P625 / psv:P625 / wikibase:geoLongitude ?lon2 . }

        # String für die Linie zusammenbauen
        BIND(CONCAT('LINESTRING (', STR(?lon1), ' ', STR(?lat1), ',', STR(?lon2), ' ', STR(?lat2), ')') AS ?str) .
        BIND(STRDT(?str, geo:wktLiteral) AS ?line) 
    }
}}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" }
}

Query found at

• https://www.wikidata.org/wiki/User:Methodios/Dresden
• https://www.wikidata.org/wiki/User:Stefan_K%C3%BChn/Dresden