query-8d31e07c700b373abf507713f39a8802

rq turtle/ttl

Propertiesinstance of (P31)PM20 subject code (P8484)main subject (P921)PM20 folder ID (P4293)number of works accessible online (P5592)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
select ?top ?topCode ?topLabel ?folderCount ?docCount
where {
  {
    select ?topCode (count(*) as ?folderCount) (sum(?folderDocCount) as ?docCount)
    where {
      ?item wdt:P31 wd:Q91257459 .
      ?item p:P921 ?statement .
      ?statement pq:P8484 ?subjectCode .
      bind(substr(?subjectCode, 1, 1) as ?topCode)
      optional {
        ?item p:P4293 ?statement2 .
        ?statement2 pq:P5592 ?folderDocCount .
        filter(isLiteral(?folderDocCount))
      }
    }
    group by ?topCode
  }
  ?top wdt:P31 wd:Q92707903 ;
       wdt:P8484 ?topCode .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en". }
}
order by desc(?folderCount)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_20th_Century_Press_Archives/Use_cases