query-88e19fe48242bef40132ba7c914b086d

rq turtle/ttl

Dictionnaire d'images allemand pour les jeunes enfants

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# Dictionnaire d'images allemand pour les jeunes enfants
# NB: lorsque 2 images ou plus sont produites pour le même lemme, il manque un rang préféré pour le Q-élément.
# SVP corriger cela si vous savez comment.
# Si des termes inappropriés apparaissent, c'est probablement parce que le sens ne possède pas un P5137 (concept) correct.
# (par So9q)
#defaultView:ImageGrid
SELECT DISTINCT ?lexemeId ?lemma ?q_concept ?q_conceptDescription ?picture
WHERE {
  ?lexemeId dct:language wd:Q188; # change language here
            wikibase:lemma ?lemma;
            ontolex:sense ?sense.
  ?sense wdt:P5137 ?q_concept.
  ?q_concept wdt:P18 ?picture.
  ############
  # Exclusions
  ############
  # Exclure les concepts hors-sujet.
  MINUS {?q_concept wdt:P31 wd:Q3624078.}. # countries

  # Exclure les concepts inappropriés.
  VALUES ?minus {
  wd:Q47092 # viol
  wd:Q198   # guerre
  wd:Q124490 # violence
  wd:Q170382 # révolver
  wd:Q1576   # cigare
  #...  .. ajouter ici vos propres exclusions ..
  }.
  MINUS {?sense wdt:P5137 ?minus.}.

  # Exclure les sens non adaptés aux jeunes enfants:
  VALUES ?filter {
  wd:Q8102
  wd:Q545779
  wd:Q1521634
  wd:Q184439}.
  FILTER NOT EXISTS {?sense wdt:P6191 ?filter.}.
  # Si vous souhaitez ne voir que certains éléments, vous pouvez insérer ici une clause FILTER
  # avec expression régulière, comme dans l'exemple Lexème en anglais ci-dessus.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,mul". }
}
ORDER BY lcase(?lemma) # order a-z

Query found at

• https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/queries/examples/fr