query-867bfa9429c5bae5bd02fed7452ac302

rq turtle/ttl

Population ]reply[15:36, 12 September 2018 (UTC)) talk (Vojtěch Dostál have population numbers for different years. Can you set the most up-to-date number as preferred? (Or are you actually doing this already?) Thank you very much --Q2351309Hi, items such as I just stumbled upon the same problem when uploading new population figures with quickstatements: Not only my own updates, but many other entries do not show up in normal queries due to outdated rankings: ]reply[07:01, 29 October 2018 (UTC)) talk (LaboramusIt does but only if there's no other preferred value.

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT 
 ?item
 ?itemLabel 
 (MAX(?pref_pop_date) as ?max_date_with_preferred_rank)
 (MAX(?norm_pop_date) as ?max_date_with_normal_rank)
WHERE 
{
 ?item p:P31 [ps:P31 wd:Q6256] # Select all countries

OPTIONAL { # Select population dates with preferred rank
 ?item p:P1082 ?pref_pop. 
 ?pref_pop wikibase:rank wikibase:PreferredRank.
 ?pref_pop pq:P585 ?pref_pop_date.
}
OPTIONAL { # Select population dates with normal rank
 ?item p:P1082 ?norm_pop. 
 ?norm_pop wikibase:rank wikibase:NormalRank.
 ?norm_pop pq:P585 ?norm_pop_date.
}
SERVICE wikibase:label {bd:serviceParam wikibase:language "en".}
}
GROUP BY ?item ?itemLabel
HAVING (
  (MAX(?pref_pop_date) < MAX(?norm_pop_date)) # There's data with normal rank available with a point in time later than the one with preferred rank
  || ((COUNT(?norm_pop_date) > 1) && !(BOUND(?max_date_with_preferred_rank)))) # There's more than one point in time, but none is flagged as preferred 
ORDER BY ?itemLabel

Query found at

• https://www.wikidata.org/wiki/User_talk:PreferentialBot