query-834ce90a5c708f7bc3ada5c118b5c93d

rq turtle/ttl

Punjabi women (birth/ language) without an article in Punjabi Wikipedia SELECT ?item ?statements ?linkcount ?itemLabel ?itemDescription?birth ?pobLabel ?death ?podLabel WHERE { ?item wdt:P31 wd:Q5 . # item is a human ?item wdt:P21 wd:Q6581072 . # gender is female { ?item wdt:P19 wd:Q22424 } # place of birth is Punjab (Q22424) UNION { ?item wdt:P19 ?pob . ?pob wdt:P131* wd:Q22424 } # place of birth within Punjab. UNION {?item wdt:P103|wdt:P1412 wd:Q58635 } # native/ spoken/ written/ signed = Punjabi language = Punjabi

OPTIONAL { ?item wdt:P569 ?birth } OPTIONAL { ?item wdt:P19 ?pob } OPTIONAL { ?item wdt:P570 ?death } OPTIONAL { ?item wdt:P20 ?pod }

OPTIONAL { ?sitelink schema:about ?item . ?sitelink schema:inLanguage "pa" } # look for articles (sitelinks) in Punjabi ("pa") FILTER (!BOUND(?sitelink)) # but select items with no such article OPTIONAL {?item wikibase:sitelinks ?linkcount. } OPTIONAL { ?item wikibase:statements ?statements .} # for counting statements SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } # for generating label } GROUP BY ?item ?statements ?linkcount?itemLabel ?itemDescription?birth ?pobLabel ?death ?podLabel ORDER BY DESC(?linkcount) #Sorted by amount of articles in other languages.

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#Punjabi women (birth/ language) without an article in Punjabi Wikipedia
SELECT ?item ?statements ?linkcount ?itemLabel ?itemDescription?birth ?pobLabel ?death ?podLabel
WHERE {
  ?item wdt:P31 wd:Q5 .         # item is a human
  ?item wdt:P21 wd:Q6581072 .   # gender is female
  { ?item wdt:P19 wd:Q22424 }   # place of birth is Punjab (Q22424) 
     UNION  { ?item wdt:P19 ?pob . 
              ?pob wdt:P131* wd:Q22424 } # place of birth within Punjab. 
     UNION {?item wdt:P103|wdt:P1412 wd:Q58635 } # native/ spoken/ written/ signed = Punjabi language = Punjabi

OPTIONAL { ?item wdt:P569 ?birth  }
OPTIONAL { ?item wdt:P19 ?pob  }
OPTIONAL { ?item wdt:P570 ?death  }
OPTIONAL { ?item wdt:P20 ?pod  }  

 OPTIONAL { ?sitelink schema:about ?item . 
          ?sitelink schema:inLanguage "pa" }    # look for articles (sitelinks) in Punjabi ("pa") 
 FILTER (!BOUND(?sitelink))    # but select items with no such article
 OPTIONAL  {?item wikibase:sitelinks ?linkcount. }
 OPTIONAL { ?item wikibase:statements ?statements .} # for counting statements
 SERVICE wikibase:label 
  { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } # for generating label
}
GROUP BY ?item ?statements ?linkcount?itemLabel ?itemDescription?birth ?pobLabel ?death ?podLabel
ORDER BY DESC(?linkcount)  #Sorted by amount of articles in other languages.

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Punjab/Queries