query-7d69da828e6708bbc085c18bd62e59ab

rq turtle/ttl

afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution française

afficher le lieu où est située l'institution.

classer les institution par ordre de nombre d'éléments décroissant.

SELECT ?institution ?institutionLabel (GROUP_CONCAT(DISTINCT(?lieuLabel); separator=", ") as ?lieuxLabel) (COUNT(DISTINCT ?item) AS ?total) WHERE { ?item wdt:P485 ?institution . #les éléments doivent disposé de la propriété "archivé par" qui renvoie à une institution. ?institution wdt:P17 wd:Q142; #l'institution doit être localisée en France wdt:P131 ?lieu. #localisation administrative de l'institution SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". ?institution rdfs:label ?institutionLabel. ?lieu rdfs:label ?lieuLabel.} } GROUP BY ?institution ?institutionLabel ORDER BY DESC (?total)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
#afficher le nombre d'éléments disposant de la propriété "archivé par" (P485) par institution française
#afficher le lieu où est située l'institution.
#classer les institution par ordre de nombre d'éléments décroissant.
SELECT ?institution ?institutionLabel (GROUP_CONCAT(DISTINCT(?lieuLabel); separator=", ") as ?lieuxLabel) (COUNT(DISTINCT ?item) AS ?total) 
WHERE 
{
  ?item wdt:P485 ?institution . #les éléments doivent disposé de la propriété "archivé par" qui renvoie à une institution.
  ?institution wdt:P17 wd:Q142; #l'institution doit être localisée en France
               wdt:P131 ?lieu. #localisation administrative de l'institution
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". 
                          ?institution rdfs:label ?institutionLabel.
                          ?lieu rdfs:label ?lieuLabel.}
}
GROUP BY ?institution ?institutionLabel
ORDER BY DESC (?total)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2020/04
• https://www.wikidata.org/wiki/Wikidata_talk:Events/AAFSaint%C3%8919