query-7bb67fbc7f69f62fa0bb12a14ffd5c80

rq turtle/ttl

Languages and writing scripts by country of citizenship

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT ?country ?countryLabel (GROUP_CONCAT(DISTINCT ?lang; separator=', ') AS ?langs) (GROUP_CONCAT(DISTINCT ?scriptL; separator=', ') AS ?scripts) (COUNT(DISTINCT ?item) AS ?cnt) WHERE {
   {
  SELECT DISTINCT ?item WHERE {
    ?item p:P106/ps:P106/wdt:P279* wd:Q26270618
  }
}.
  ?item wdt:P27 ?country .
  OPTIONAL {
    ?country wdt:P37 ?language .
    ?language rdfs:label ?lang .
    FILTER(LANG(?lang) = 'en') .
    OPTIONAL {
      ?language wdt:P282 ?script .
      ?script rdfs:label ?scriptL .
      FILTER(LANG(?scriptL) = 'en') .
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'en' }
} GROUP BY ?country ?countryLabel ORDER BY DESC(?cnt)

Query found at

• https://www.wikidata.org/wiki/User:MisterSynergy/rowing/queries