query-744c04a56388b7a091f6090903e58921

rq turtle/ttl

Mapa de países miembros de la unión europea coloreado por densidad de población (habitantes por km2)

Use at

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Map
Prefix commons:<http://commons.wikimedia.org/data/main/Data:> 
SELECT ?pais ?paisLabel ?poblacion ?area ?densidad ?mapaPais ?rgb 
WHERE {
  ?pais wdt:P463 wd:Q458;
    wdt:P1082 ?poblacion;
    wdt:P2046 ?area.
  OPTIONAL { ?pais wdt:P3896 ?mapaPais. }
  FILTER(NOT EXISTS {
    ?pais p:P463 ?statement.
    ?statement ps:P463 wd:Q458;
      pq:P582 ?fecha_fin.
  })
  BIND(?poblacion / ?area AS ?densidad)
  BIND(IF(?densidad < 50 , "ffebee", IF(?densidad < 100 , "ef9a9a", 
       IF(?densidad < 200 , "ef5350", 
       IF(?densidad < 300 , "c62828", "7f0000")))) AS ?rgb)
  BIND(IF(?pais = wd:Q29999, commons:Nederland.map, 
       ?mapaPais) AS ?mapaPais)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY (?densidad)

Query found at