query-73b9b4c0429423f0d78e168514215087

rq turtle/ttl

All itch.io URLs SELECT ?item ?itemLabel (SAMPLE(?typeLabel) as ?nature) ?propertyLabel ?url WITH { SELECT ?property WHERE { ?property rdf:type wikibase:Property. ?property wikibase:propertyType wikibase:Url . } } AS %properties WITH { SELECT ?item ?url ?property WHERE { INCLUDE %properties . ?property wikibase:directClaim ?wdt. ?item ?wdt ?url. FILTER regex (STR(?url), "itch.io"). } } AS %items WHERE { INCLUDE %items. ?item wdt:P31 ?type. SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". ?type rdfs:label ?typeLabel. ?item rdfs:label ?itemLabel. ?property rdfs:label ?propertyLabel. } } GROUP BY ?item ?itemLabel ?propertyLabel ?url

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX bd: <http://www.bigdata.com/rdf#>
# All itch.io URLs 
SELECT ?item ?itemLabel (SAMPLE(?typeLabel) as ?nature) ?propertyLabel ?url
WHERE {
   {
  SELECT ?item ?url ?property WHERE {
     {
  SELECT ?property WHERE {
    ?property rdf:type wikibase:Property.
    ?property wikibase:propertyType wikibase:Url .
  }
}.
    ?property wikibase:directClaim ?wdt.
    ?item ?wdt ?url.
    FILTER regex (STR(?url), "itch.io").
  }
}
  ?item wdt:P31 ?type.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
    ?type rdfs:label ?typeLabel.
    ?item rdfs:label ?itemLabel.
    ?property rdfs:label ?propertyLabel.
  }
} GROUP BY ?item ?itemLabel ?propertyLabel ?url

Query found at

• https://www.wikidata.org/wiki/Wikidata:Property_proposal/Identifiant_itch.io