query-692b0e0bce07057696807ae161d9007f

rq turtle/ttl

All software items that have at least one TaDiRAH ID (indirectly via Property:P366)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT
  ?method ?methodLabel ?tadirahID
  (?methodColor AS ?rgb)
  ?tool ?toolLabel ?toolDesc
  ?image # order is relevant for the graph display.
WHERE {
   {
  SELECT DISTINCT
    ?tool ?method ?methodColor
  WHERE {
    # select all items that have a TaDiRAH ID
    ?method wdt:P9309 ?tadirahID.
    BIND("7eb8ff" AS ?methodColor) # set rgb colour for method nodes
    # select all items which are linked to the methods through `has use`
    ?tool wdt:P366 ?method;
      # limit tools to software in the broadest sense
      wdt:P31/wdt:P279* wd:Q7397.
    }
  LIMIT 3000
}  # retrieve the logos and images for those tools that have them
  OPTIONAL { ?tool (wdt:P154| wdt:P18) ?image .}
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?tool rdfs:label ?toolLabel;
      schema:description ?toolDesc.
    ?method rdfs:label ?methodLabel.
  }
}
ORDER BY ?toolLabel
LIMIT 5000

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_DH_Tool_Registry/How_to_Use