query-64c4f67eba7f8bd29709a56fa52f7538

rq turtle/ttl

title:list of recorded track from one specific composition, and all the releases (single/album, etc.) where using SELECT distinct ?item ?itemLabel ?tipusLabel ?interpret ?interpretLabel ?productorLabel ?album ?albumLabel ?pista ?data_publi WHERE { SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

?item wdt:P2550 wd:Q1550581. OPTIONAL { ?item wdt:P31 ?tipus_trk. } OPTIONAL { ?item wdt:P175 ?interpret. } OPTIONAL { ?item wdt:P10135 ?data_enreg. } OPTIONAL { ?item wdt:P483 ?gravat_a. } OPTIONAL { ?item wdt:P162 ?productor. } OPTIONAL { ?album p:P658 ?statement. ?statement ps:P658 ?item. OPTIONAL {?statement pq:P1545 ?pista_ord.} OPTIONAL {?statement pq:P3831 ?pista_rol.} OPTIONAL { ?album wdt:P31 ?tipus_rls. } OPTIONAL { ?album wdt:P577 ?data_publi. } OPTIONAL { ?album wdt:P437 ?format_dist. } } BIND(IF(BOUND(?tipus_rls), ?tipus_rls, ?tipus_trk ) as ?tipus). BIND(IF(BOUND(?pista_ord), ?pista_ord, ?pista_rol) as ?pista). } ORDER BY ASC(?data_enreg) ASC(?interpretLabel) ASC(?album)

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#title:list of recorded track from one specific composition, and all the releases (single/album, etc.) where using
SELECT distinct ?item ?itemLabel ?tipusLabel ?interpret ?interpretLabel ?productorLabel
 ?album ?albumLabel ?pista ?data_publi WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

 ?item wdt:P2550 wd:Q1550581.
  OPTIONAL { ?item wdt:P31 ?tipus_trk. }
  OPTIONAL { ?item wdt:P175 ?interpret. }
  OPTIONAL { ?item wdt:P10135 ?data_enreg. }
  OPTIONAL { ?item wdt:P483 ?gravat_a. }
  OPTIONAL { ?item wdt:P162 ?productor. }
  OPTIONAL { ?album p:P658 ?statement.
       ?statement ps:P658 ?item.
       OPTIONAL {?statement pq:P1545 ?pista_ord.}
       OPTIONAL {?statement pq:P3831 ?pista_rol.}
       OPTIONAL { ?album wdt:P31 ?tipus_rls. }
       OPTIONAL { ?album wdt:P577 ?data_publi. }
       OPTIONAL { ?album wdt:P437 ?format_dist. }
           }
  BIND(IF(BOUND(?tipus_rls), ?tipus_rls, ?tipus_trk )
           as ?tipus).
  BIND(IF(BOUND(?pista_ord), ?pista_ord, ?pista_rol)
           as ?pista).
}
ORDER BY ASC(?data_enreg) ASC(?interpretLabel) ASC(?album)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2022/06