query-60fefa4f9b2d4a64e7c0aea80d379a85

rq turtle/ttl

title:Chancellors of the Exchequer and time served in office SELECT ?item ?itemLabel ?start ?end ?image ?link ?partyLabel ?ps_start ?ps_end WHERE { ?item p:P39 ?s. ?s ps:P39 wd:Q531471. ?s pq:P580 ?start. OPTIONAL {?s pq:P582 ?end.} OPTIONAL {?item wdt:P18 ?image.} OPTIONAL {?item wdt:P1417 ?id.} OPTIONAL {?item p:P102 ?ps. ?ps ps:P102 ?party. OPTIONAL { ?ps pq:P580 ?ps_start.} OPTIONAL { ?ps pq:P582 ?ps_end.}

        # It is faster not to use ?start and ?end here. The next lines will avoid timeout:
        OPTIONAL { ?s pq:P582 ?pos_end.} 
        ?s pq:P580 ?pos_start

        # Check that party membership did not start after end of postion:
        FILTER (IF(BOUND(?ps_start) && BOUND(?pos_end), ?ps_start < ?pos_end, true))
        # Check that party membership did not end before start of postion;
        FILTER (IF(BOUND(?ps_end), ?ps_end > ?pos_start, true))

} BIND(IF(BOUND(?id), URI(CONCAT("https://www.britannica.com/",?id)) , ?item) AS ?link) SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } } ORDER BY ?start

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#title:Chancellors of the Exchequer and time served in office
SELECT ?item ?itemLabel ?start ?end ?image ?link ?partyLabel ?ps_start ?ps_end WHERE {
  ?item p:P39 ?s.
  ?s ps:P39 wd:Q531471.
  ?s pq:P580 ?start. 
  OPTIONAL {?s pq:P582 ?end.}
  OPTIONAL {?item wdt:P18 ?image.}
  OPTIONAL {?item wdt:P1417 ?id.}
  OPTIONAL {?item p:P102 ?ps.
            ?ps ps:P102 ?party.
            OPTIONAL { ?ps pq:P580 ?ps_start.}
            OPTIONAL { ?ps pq:P582 ?ps_end.}

            # It is faster not to use ?start and ?end here. The next lines will avoid timeout:
            OPTIONAL { ?s pq:P582 ?pos_end.} 
            ?s pq:P580 ?pos_start

            # Check that party membership did not start after end of postion:
            FILTER (IF(BOUND(?ps_start) && BOUND(?pos_end), ?ps_start < ?pos_end, true))
            # Check that party membership did not end before start of postion;
            FILTER (IF(BOUND(?ps_end), ?ps_end > ?pos_start, true))
  }
  BIND(IF(BOUND(?id), URI(CONCAT("https://www.britannica.com/",?id)) , ?item) AS ?link)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY ?start

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2022/01