query-6044da04b668d0db52d44d6488600c60

rq turtle/ttl

Botanists with more than one author abbreviationWikidata:Database reports/Constraint violations/P586#"Single value" violations Wikidata:Database reports/Constraint violations/P428#"Scope" violations

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT DISTINCT ?item ?itemLabel ?count ?sample1  ?sample2  ?exception
WHERE
{
    {
        SELECT ?item (COUNT(?value) AS ?count) (MIN(?value) AS ?sample1) (MAX(?value) AS ?sample2) {
            ?item p:P428 [ ps:P428 ?val; wikibase:rank ?rank ] .
            FILTER( ?rank != wikibase:DeprecatedRank ) .
             {
    SELECT ?formatter WHERE {
        OPTIONAL { wd:P428 wdt:P1630 ?formatter }
    } LIMIT 1
}.
            BIND( IF( BOUND( ?formatter ), URI( REPLACE( ?formatter, '\\$1', ?val ) ), ?val ) AS ?value ) .
        } GROUP BY ?item HAVING ( ?count > 1 )
    } .
    OPTIONAL {
        wd:P428 p:P2302 [ ps:P2302 wd:Q19474404; pq:P2303 ?exc ] .
        FILTER( ?exc = ?item ) .
    } .
    BIND( BOUND( ?exc ) AS ?exception ) .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } .
}
ORDER BY DESC(?count)

Query found at

• https://www.wikidata.org/wiki/User:Korg/queries