query-59fcfff8196447450f6c53e81b2bce0b

rq turtle/ttl

Christian Ferrer?de wdt:P171* wd:Q15711568

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX schema: <http://schema.org/>
PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:ImageGrid

SELECT ?file ?image ?stype ?stypeLabel ?collec ?collecLabel ?role ?roleLabel ?de ?deLabel
WHERE {
  ?file wdt:P180 ?stype ; schema:contentUrl ?url .

  bind(iri(concat("http://commons.wikimedia.org/wiki/Special:FilePath/", replace(substr(str(?url),53),"_","%20"))) AS ?image) .

  #?file wdt:P180  wd:Q105607273  .
   {
  select ?stype ?stypeLabel ?collec ?collecLabel ?role ?de ?roleLabel ?deLabel {
   service <https://query.wikidata.org/sparql> {
     select ?stype ?stypeLabel ?collec ?collecLabel ?role ?de ?roleLabel ?deLabel { 
       ?stype wdt:P31/wdt:P279* wd:Q51255340 
       SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       optional {
         ?stype wdt:P195 ?collec .
       }
       ?stype p:P2868 [ps:P2868 ?role ; pq:P642 ?de] .
       #enlevez les # au dessous pour préciser une ou des collections
       #values ?collec {
       # wd:Q122945 # exemple avec le Yale Peabody Museum of Natural History 
       #}
       ?de wdt:P171* wd:Q15711568 . # choisir un taxon dont on cherche les types, incluant les types de ses sous-taxons
     }
   }
  }
}}

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2021/02