query-595a5f43910ff1785c2db4aa783899b3

rq turtle/ttl

Operas in the Order of their First Performance Operas in the Order of their First Performance Opera's in de volgorde van eerste uitvoering

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX bd: <http://www.bigdata.com/rdf#>
SELECT (replace(group_concat(distinct ?composer;separator="; "), "http://www.wikidata.org/entity/", "") as ?composers)  #Strip the path in order to get only the Q-number.
       (group_concat(distinct ?composerLabel;separator="; ") as ?composerLabels)
       ?opera 
       ?operaLabel 
       ?languageLabel 
       ?worldpremiere
WHERE 
{
  ?opera wdt:P31/wdt:P279* wd:Q1344.
  ?opera wdt:P1191 ?worldpremiere .
  OPTIONAL { ?opera wdt:P86 ?composer }
  OPTIONAL { ?opera wdt:P86/rdfs:label ?composerLabel . FILTER (lang(?composerLabel) = "en") }
  OPTIONAL { ?opera wdt:P407 ?language }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,fr,it,es,ru" }
}
GROUP BY ?opera
         ?operaLabel
         ?languageLabel 
         ?worldpremiere

ORDER BY ASC(?worldpremiere)

Query found at

• https://www.wikidata.org/wiki/Wikidata:WikiProject_Performing_arts/Tools_%26_tasks
• https://www.wikidata.org/wiki/Wikidata:WikiProject_Performing_arts/Tools_%26_tasks/en
• https://www.wikidata.org/wiki/Wikidata:WikiProject_Performing_arts/Tools_%26_tasks/fr
• https://www.wikidata.org/wiki/Wikidata:WikiProject_Performing_arts/Tools_%26_tasks/nl