query-538ac838c493d2d1f612150e07f88a90
(42) Graph of mitochondrial DNA relatives: Elizabeth IINo.42 (2020.07.15T1537 created)
Use at
- https://query.wikidata.org/sparql
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# find Elizabeth II's mitochondrial DNA relatives, i.e., those females who share a mitochondrial DNA common ancestor with Elizabeth II
### Note: In comparison with the previous query "Graph of mitochondrial DNA descendants of a common ancestor (maternal relatives): Elizabeth II",
### this query removes "wd:Q9682 (wdt:P25|wdt:P40)* ?mtDNA", which unnecessarily defines ?mtDNA as "Elizabeth II (Q9682)'s any mother (P25) or child (P40)'s mother or child's...".
#defaultView:Graph
SELECT DISTINCT ?mtDNA ?mtDNALabel ?birthdate ?image ?mother ?motherLabel ?edgeLabel
WHERE {
# define ?Eve as Elizabeth II (Q9682)'s any mother (P25)'s mother's...
wd:Q9682 wdt:P25* ?Eve.
# define ?mtDNA as one whose any mother (P25)'s mother's... is ?Eve
?mtDNA wdt:P25* ?Eve.
# limit ?mtDNA's gender (P21) to female (Q6581072)
?mtDNA wdt:P21 wd:Q6581072
# optional: define ?mtDNA's mother (P25) as ?mother
OPTIONAL {?mtDNA wdt:P25 ?mother.
# get P25 (mother)'s property label and allow it to appear on graph edge
?edge wikibase:directClaim wdt:P25;
a wikibase:Property}
# optional: show ?mtDNA's birthdate (P569), which only appears in table, not graph
OPTIONAL {?mtDNA wdt:P569 ?birthdate}
# optional: show ?mtDNA's image (P18), which appears directly in graph, and as link in table
OPTIONAL {?mtDNA wdt:P18 ?image}
# show label in auto language as default, and English when no default label exists
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Query found at
graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
v1("?Eve")
v5("?birthdate"):::projected
v4("?edge")
v6("?image"):::projected
v3("?mother"):::projected
v2("?mtDNA"):::projected
c7(["wikibase:Property"]):::iri
c4(["wd:Q6581072"]):::iri
c2(["wdt:P25"]):::iri
c11(["bd:serviceParam"]):::iri
c1(["wd:Q9682"]):::iri
c13(["#91;AUTO_LANGUAGE#93;,en"]):::literal
c1 -->c2--> v1
v2 -->c2--> v1
v2 --"wdt:P21"--> c4
subgraph optional0["(optional)"]
style optional0 fill:#bbf,stroke-dasharray: 5 5;
v2 -->c2--> v3
v4 -."wikibase:directClaim".-> c2
v4 --"a"--> c7
end
subgraph optional1["(optional)"]
style optional1 fill:#bbf,stroke-dasharray: 5 5;
v2 -."wdt:P569".-> v5
end
subgraph optional2["(optional)"]
style optional2 fill:#bbf,stroke-dasharray: 5 5;
v2 -."wdt:P18".-> v6
end
subgraph s1["http://wikiba.se/ontology#label"]
style s1 stroke-width:4px;
c11 --"wikibase:language"--> c13
end