query-523318c7c3baad4b3dda92bb420b6078

rq turtle/ttl

Map: Set individual colors for ordinal scaleThe following query is counting the numbers of co-authors from a specific author identified by his/her orcid grouped by the co-authors country of citizenship:

Use at

• https://query.wikidata.org/sparql

PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX bd: <http://www.bigdata.com/rdf#>
#defaultView:Map
SELECT  ?coauthor_countryLabel ?shape ?numOfCoAuthors ?layer ?rgb 
WHERE {
   {
  SELECT ?shape ?coauthor_country (COUNT(?author) AS ?numOfCoAuthors) WHERE {
     {
  SELECT ?author ?searched_author WHERE {
    # Find co-authors
    ?searched_author wdt:P496  "0000-0002-6778-0887".
    ?work wdt:P50 ?searched_author, ?author .
  }
  GROUP BY ?author  ?searched_author
}           
    # Exclude self-links
    FILTER (?searched_author != ?author)

    ?author wdt:P27 ?coauthor_country .
    ?coauthor_country wdt:P3896 ?shape.


  }GROUP BY ?shape ?coauthor_country
}  # Label the results 
  BIND(IF(?numOfCoAuthors <= 2,"< 2 Authors",
          IF(?numOfCoAuthors < 5,"< 5 Authors",
          IF(?numOfCoAuthors < 10,"< 10 Authors","> 10 Authors"))) AS ?layer).

  #Set ColorRange for Ordinal Scale
  BIND(IF(?numOfCoAuthors <= 2,"#fef0d9",
          IF(?numOfCoAuthors < 5,"#fdcc8a",
          IF(?numOfCoAuthors < 10,"#fc8d59","#d7301f"))) AS ?rgb).

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

} ORDER BY DESC(?numOfCoAuthors)

Query found at

• https://www.wikidata.org/wiki/Wikidata:Request_a_query/Archive/2020/01