query-4b961e89b4cbe5f1e11dd91d91be7f45
UK Politicians born on Friday the 13th SELECT ?item ?itemLabel ?dob WHERE { ?item wdt:P31 wd:Q5. ?item wdt:P27 wd:Q145. ?item wdt:P106 wd:Q82955. ?item wdt:P569 ?dob.
day of week algorithm from https://en.wikipedia.org/wiki/Determination_of_the_day_of_the_week#Disparate_variation
BIND(YEAR(?dob) AS ?year) BIND(MONTH(?dob) AS ?month) BIND(DAY(?dob) AS ?day) BIND(FLOOR(?year / 100) AS ?century) BIND(REPLACE( STR(?year), "^..", "") AS ?yy) BIND( IF (?month <= 2, xsd:integer(?yy) - 1, xsd:integer(?yy)) AS ?yyx) BIND( IF (?month <= 2, ?month + 10, ?month - 2) AS ?mm) BIND( ?day + FLOOR(2.6 * ?mm - 0.2) + ?yyx + FLOOR(?yyx / 4) + FLOOR(?century / 4) - 2 * ?century AS ?a) BIND( ?a - FLOOR(?a / 7) * 7 AS ?mod7) # mod7: 0 = Sunday... 6 = Saturday FILTER(?day = 13 && ?mod7 = 5) SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } }
Use at
- https://query.wikidata.org/sparql
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX bd: <http://www.bigdata.com/rdf#>
# UK Politicians born on Friday the 13th
SELECT ?item ?itemLabel ?dob WHERE {
?item wdt:P31 wd:Q5.
?item wdt:P27 wd:Q145.
?item wdt:P106 wd:Q82955.
?item wdt:P569 ?dob.
# day of week algorithm from https://en.wikipedia.org/wiki/Determination_of_the_day_of_the_week#Disparate_variation
BIND(YEAR(?dob) AS ?year)
BIND(MONTH(?dob) AS ?month)
BIND(DAY(?dob) AS ?day)
BIND(FLOOR(?year / 100) AS ?century)
BIND(REPLACE( STR(?year), "^..", "") AS ?yy)
BIND( IF (?month <= 2, xsd:integer(?yy) - 1, xsd:integer(?yy)) AS ?yyx)
BIND( IF (?month <= 2, ?month + 10, ?month - 2) AS ?mm)
BIND( ?day + FLOOR(2.6 * ?mm - 0.2) + ?yyx + FLOOR(?yyx / 4) + FLOOR(?century / 4) - 2 * ?century AS ?a)
BIND( ?a - FLOOR(?a / 7) * 7 AS ?mod7)
# mod7: 0 = Sunday... 6 = Saturday
FILTER(?day = 13 && ?mod7 = 5)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}